Ein einfacher script in java, der .txt dateien zusammenfügt

@echo off & setlocal

::Hier Quell- und Zielverzeichnis setzen
set "SrcDir=Quellverzeichnis"  
set "DestDir=Zielverzeichnis ohne abschließenden Backslash"  

::Hier können mehrere Monate eingetragen werden,
::immer durch ein Leerzeichen getrennt
set "Month=März April"  

::Quellverzeichnis zum aktuellen Verzeichnis machen
pushd "%SrcDir%"  

::Die erste Schleife iteriert über die Nummern der Elemente
for /l %%i in (1,1,8) do (
  ::Die zweite Schleife iteriert über die Monate
  for %%m in (%Month%) do (
    ::Zieldatei mit leerem Inhalt anlegen
    type NUL > "%DestDir%\Element %%i Monat %%m.txt"  

    ::Die dritte Schleife iteriert über die gefundenen Dateien
    for /f "delims=" %%f in ('dir /b /o:n "Element %%i-*.%%m.txt" 2^>NUL') do (  
      ::Die Zieldatei und die gerade behandelte Quelldatei werden im Binärmodus zu einer Datei zusammenkopiert
      copy /b "%DestDir%\Element %%i Monat %%m.txt" + "%%f" "%DestDir%\Element %%i Monat %%m.txt" > NUL  
    )
  )
)

::Verzeichnis, das vor dem Start des Scripts das aktuelle Verzeichnis war,
::wieder zum aktuellen Verzeichnis machen
popd