Fehlersuche - Falsche Aussgabe in txt

@ echo off & setlocal
chcp 1252>nul
set ue=ü
set ae=ä
set oe=ö
set Uue=Ü
set Aae=Ä
set Ooe=Ö
set ss=ß
chcp 850>nul
title Backupper f%ue%r CoD4

echo Das Programm wird gestartet.
echo.
echo Bitte Warten...
echo.
echo. 
echo. 

echo ::._Ben%oe%tigte Variablen werden gesetzt_.::
echo.
echo Bitte Warten...
echo.
set "installpath="  
REG QUERY "hklm\SOFTWARE\Activision\Call of Duty 4" /V InstallPath >NUL 2>&1 || goto :enderror  
FOR /F "Skip=2 tokens=2*" %%i IN ('reg query "hklm\SOFTWARE\Activision\Call of Duty 4" /V "InstallPath"') do set "installpath=%%j"  
if not defined installpath goto :enderror

set "codkey="  
REG QUERY "hklm\SOFTWARE\Activision\Call of Duty 4" /V codkey >NUL 2>&1 || goto :enderror  
FOR /F "Skip=2 tokens=2*" %%i IN ('reg query "hklm\SOFTWARE\Activision\Call of Duty 4" /V "codkey"') do set "codkey=%%j"  
if not defined codkey goto :enderror

set "key="  
set "key=%codkey:~,4%-%codkey:~4,4%-%codkey:~8,4%-%codkey:~12,4%-%codkey:~16%"  

set "FS="  
set "FS=%temp%\GetFolderSize.vbs  

set "ZO="  
set "ZO=Backup\Players\profiles"  

set "Maxsize="  
set "Maxsize=0"  
echo ::._Variablen wurden erfolgreich gesetzt_.::
echo.
goto cont

:restart1
echo Sie haben eine leere Auswahl getroffen. 
echo Bitte die Auswahl wiederholen.
echo.
:cont
echo Taste S = Key und die Profile sichern
echo Taste W = Profile wiederherstellen
echo Taste X = Programm schlie%ss%en
echo.
set "question1="  
set /p question1=Bitte S  oder  W  oder  X  eingeben: 
if not defined question1 goto :restart1
echo.
if /i %question1:~,1%==S goto :backup
if /i %question1:~,1%==W goto :copy
if /i %question1:~,1%==x goto :endalt


:copy
if not exist Backup\Players\profiles/nul goto :nota 
echo WScript.Echo Int(CreateObject("Scripting.FileSystemObject").GetFolder(WScript.Arguments(0)).Size/1024/1024+.99)>%FS%  
for /f %%i in ('cscript //nologo %FS% "%ZO%"') do set OGr=%%i  
del %FS%
if %OGr% EQU %Maxsize% goto :nota
echo Die Profile werden nun wiederhergestellt:
xcopy "Backup\Players" "%installpath%players" /S /E /Y /I /Q  
if %errorlevel% == 1 goto :enderror
echo Die  Profile wurden erfolgreich wiederhergestellt.
goto end


:backup
echo.
echo ::._Ben%oe%tigte Verzeichnisse werden erstellt_.::
echo.
echo Bitte Warten...
echo.

md "Backup" 2>nul  
md "Backup\Players" 2>nul  

echo ::._Verzeichnisse wurden erfolgreich erstellt_.::
echo.
echo.
echo.
echo Ihr aktueller Key ist "%key%"  
echo Er befindet sich im Backup-Ordner (codkey.txt)
> "Backup\codkey.txt" echo Der gesicherte Schlüssel ist:  
>>"Backup\codkey.txt" echo %key%  
>>"Backup\codkey.txt" echo Bewahren sie den Key bis zu nächsten Neuinstallation von CoD4 auf.  
>>"Backup\codkey.txt" echo Sie können den Key dann wieder zu Installation nutzen, und haben zudem die passenden Profile für den Key  
echo.
echo Die Profile werden nun gesichert:
xcopy "%installpath%\players" "Backup\Players\" /S /E /Y /I /Q  
if %errorlevel% == 1 goto :enderror
echo Die  Profile wurden erfolgreich gesichert.
goto :end


:endalt
echo Sie haben das Programm ge%oe%ffnet, um es zu schlie%ss%en
echo Das ist eine berauschende Logik
echo Danke f%ue%r die Benutzung meines Programms
echo Das Programm beendet sich von selbst
ping localhost -n 5 >nul
goto :eof
:end
color 2F
echo.
echo Der Vorgang wurde abgeschlossen
echo Danke f%ue%r die Benutzung meines Programms
if /i %question1:~,1%==S goto :S
if /i %question1:~,1%==W goto :W
:S
color 2F
echo Der Ordner "Backup" wird beim Beenden ge%oe%ffnet  
echo Beliebige Taste zum Beenden dr%ue%cken
pause >nul
start "Backup" "Backup"  
goto :eof
:W
color 2F
echo Der CoD4-Ordner wird beim Beenden ge%oe%ffnet
echo Beliebige Taste zum Beenden dr%ue%cken
pause >nul
start "CoD4" "%installpath%"  
goto :eof
:enderror
color 4F
echo !!ERROR:Es ist ein Fehler aufgetreten!!
echo Das Programm wird nun geschlossen
ping localhost -n 5 >nul
goto :eof
:nota
color 4F
echo !!ERROR:Es sind keine Profile vorhanden!!
echo Das Programm wird nun geschlossen
ping localhost -n 5 >nul
pause >nul
goto :eof