for Schleife mit Unterverzeichnissen

Hallo zusammen!

Ich habe bereits das passende Skript von Biber gefunden, nur leider läuft das nur im aktuellen Verzeichnis und nimmt nicht alle Unterverzeichnisse mit.

Folgendes soll geschehen:
- suche in allen Unterverzeichnissen alle msg-Dateien durch nach dem String xyz
- wenn du xyz in irgendeiner msg-Datei in irgendeiner Zeile findest, lösche die komplette Zeile
- die modifizierte Datei soll im selben Verzeichnis mit selben Namen bestehen bleiben

folgendes Skript von Biber läuft einwandfrei, aber nimmt eben nur das aktuelle Verzeichnis mit:
@echo off & setlocal
for %%i in (*.msg) DO (
findstr /v /b /i "xyz" "%%~fi">"%%~fi.bak"
move "%%~fi.bak" "%%~fi"
)


Wie kann ich das erweitern auf Unterverzeichnisse?


Danke vorab und Grüße,

Markus.

@echo off & setlocal
for /f "delims=" %%i in ('dir /s /b *.msg') do (  
    findstr /v /b /i "xyz" "%%i">"%%i.bak"  
    move "%%i.bak" "%%i"  
)

@echo off & setlocal
for /f "delims=" %%i in ('dir /s /b *.msg') do (  
    findstr /b /i "xyz" "%%i">nul && (  
        findstr /v /b /i "xyz" "%%i">"%%i.bak"  
        move "%%i.bak" "%%i">nul  
    )
)

@echo off
REM noch überflüssig:  & setlocal
for /f "delims=" %%i in ('findstr /s /m /b /i "xyz" "D:\einverz\*.msg"') do (  
        findstr /v /b /i "xyz" "%%i">"%%i.bak"  
        move "%%i.bak" "%%i">nul  
)