MSSQL: Datensicherung Meldung 3023

BACKUP DATABASE [db_kunde] TO  DISK = N'D:\MSSQL\Backup\db_kunde.bak' WITH NOFORMAT, INIT,  NAME = N'Datenbank Sichern', SKIP, NOREWIND, NOUNLOAD,  STATS = 10  
GO

@echo off
rem *** Das Skript erstellt eine Sicherung, komprimiert diese in einen entsprechenden Wochentag
rem ***
rem ***

rem *** ACHTUNG: Es muss das Prgramm 7-Zip installiert sein - Pfad der 7z.exe eintragen
rem *** Beispiel: SET ZIPEXE="C:\Program Files\7-zip\7z.exe"  
SET ZIPEXE=<Pfad zur Installation von 7zip.exe>

rem *** Pfad SQL Express DB-Server eintragen und Pfad des SQL-Skripts eintragen
rem *** Beispiel: SET BACKUPPFAD=D:\MSSQL\Backup\
SET BACKUPPFAD=<Pfad inkl. \ zum Sicherungsverzeichnis>

rem *** Pfad für das SQL-Skript der Datensicherung eintragen
rem *** Beispiel: SET SQLSKRIPT=D:\DBTools\SQLBackup.sql
SET SQLSKRIPT=<Pfad + Daten zum SQL Backup Skript>

rem *** Datebankservername eintragen
rem *** Beispiel: SET SQLSRV=SQLEXPRESS
SET SQLSRV=<SQL Server Instanz>


rem *** Start der Datenbanksicherung
sqlcmd -E -S %SQLSRV% -i %SQLSKRIPT%

rem *** Ermitteln des Wochentags
FOR /F "tokens=1,2,3 delims=." %%a in ('echo %date%') do set yy=%%c & set mm=%%b & set dd=%%a   
set /a "TwoDigitYearMax=2038%%1000"   
if 1%yy% LSS 200 if 1%yy% LSS 1%TwoDigitYearMax% (set yy=20%yy%) else (set yy=19%yy%) 
set /a dd=100%dd%%%100,mm=100%mm%%%100 
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2 
set /a dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1 
If %dow% equ 1 set "WoTa=Montag"   
If %dow% equ 2 set "WoTa=Dienstag"   
If %dow% equ 3 set "WoTa=Mittwoch"   
If %dow% equ 4 set "WoTa=Donnerstag"   
If %dow% equ 5 set "WoTa=Freitag"   
If %dow% equ 6 set "WoTa=Samstag"   
If %dow% equ 7 set "WoTa=Sonntag"   

rem *** Sicherungsdatei kompremieren mit 7-ZIP nach EXTERN
IF NOT EXIST %BACKUPPFAD%%WoTa% mkdir %BACKUPPFAD%%WoTa%
%ZIPEXE% a -y %BACKUPPFAD%%WoTa%\db_kunde.zip %BACKUPPFAD%db_kunde.bak