Papierkorb einrichten auf einer externen Festplatte, aber wie???

@echo off
setlocal
set "Recycle=Trash"  
set "wait=5"  
if "%~1" equ "/?" goto :help  
if "%~1" equ "/i" if "%~2" neq "" (goto :setup ) else goto :help  
if "%~1" equ "" goto :List  

:Time
set "DelTime=%DATE% %TIME:,="%  
set "Deltime=%deltime::=-%"  
set "Typ=(DIR) "  
if not exist "%~1\" set "Typ= file "  
if not exist %1 echo >&2 Datei "%~1" nicht gefunden!& exit /b 1  
set "FileName=%~nx1"  
 rem wenn Ordnername mit Backslash
::if not defined Filename for %%i in ("%~1\.") do set "FileName=%"~nxi"  

:UNC
if %~d1 equ \\ for /f "tokens=1-3* delims=\" %%a in ("%~1") do (  
  if /i "%%a" equ "%COMPUTERNAME%" echo  Information:  Eigener Netzwerkpfad!  
  if "%%c" equ "" goto :List  
  set "Unc=%~d1%%a\%%b"  
  for /f "tokens=1-4 delims=\" %%i in ("%~1") do if "%%l" neq "" set "Orig=%~d1%%i\%%j\%%k\%%l"  
  if /i "%%c" equ "%Recycle%" if defined orig (goto :Restore ) else goto :List  
  for /f "tokens=2* delims=\" %%i in ("%~p1") do set "Pfad=\%%j"  
  goto :Backup
)


:USE
for /f %%i in ('net use ^|find ":" ') do if %~d1 equ %%i goto :Pfad  

:NO
echo Datei "%~1" nicht im NetzwerkPfad oder Freigabe.  
 rem eventuell USB
(for /f "usebackq tokens=1* delims=:" %%i in ("%~d1\%Recycle%\%Recycle%.inf") do vol %~d1|find ":%%j" >nul  
) || >&2 echo Kein Papeirkorb eingerichtet! && set /a B=3 && goto :end
goto :Pfad
if "%~2" neq "" (shift &goto :Time ) else goto :end  

:Pfad
set "Unc=%~d1"  
set "Pfad=%~p1"  
set "Orig="  
for /f "tokens=1* delims=\" %%a in ("%~1") do (  
  if "%%b" equ "" goto :List  
  for /f "tokens=1-3 delims=\" %%i in ("%~1") do if "%%k" neq "" set "Orig=%%i\%%j\%%k"  
  for /f "delims=\" %%c in ("%%b") do if /i "%%c" equ "%Recycle%" if defined orig (goto :Restore ) else goto :List  
)

:Backup
set "Z=%Unc%\%Recycle%\%Deltime% %Typ% %FileName%%Pfad%"  
if not exist "%Z%" md "%Z%" || exit /b 2  
move %1 "%Z%"  
if "%~2" neq "" shift &goto :Time  

:DelOld
if not defined fo set /a fo=-1
for /f "tokens=3,5" %%i in ('dir /-c /s "%Unc%\%Recycle%" ^|find /v ":" ') do if not "%%j" equ "" (set "F=%%i" ) else set "E=%%i"  
for %%i in (F E ) do call set "%%i=%%%%i:~0,-6%%"     
for %%i in (F E ) do set /a %%i=%%i
 rem 25 Prozent abfragen
set /a F/=4
if %F% geq %E% goto :end
for /f "tokens=1* delims=:" %%i in ('dir /ad /b /od "%Unc%\%Recycle%" ^|findstr /n . ^|findstr /b 1: ' ) do if "%last%" neq "%%j" (echo %%j endgueltig loeschen?  
 rd /s "%Unc%\%Recycle%\%%j"  
 set "Last=%%j" ) else goto :end  
goto :Delold


goto :end

:Restore
call :MoveintTree "%Orig%" "%UNC%" /q  
if "%~2" neq "" (shift &goto :Time ) else goto :end  

:List

if "%~1" equ "" for /f %%i in ('net use ^|find ":" ') do echo  Papierkorb von "%Unc%\%Recycle%" &dir /ad /b /od "%%i\%Recycle%"  
if "%~1" neq "" echo  Papierkorb von "%Unc%\%Recycle%" &dir /ad /b "%Unc%\%Recycle%"  
if "%~2" neq "" (shift &goto :Time ) else goto :end  


:Setup
set "Q=N"  
echo(
dir /ad %~d2\$Recycle* %~d2\%Recycle% |findstr /v "von" |more /S  
chkdsk %~d2 ||echo(&&echo  Eventuell ist der Papierkorb von Windows auf dieser Partition aktiv!
set /p Q="Papierkorb auf %~d2 einrichten? J/N  "  
cmd /von /c "echo  !Q! "|find /i " J " ||echo Abbruch! && set /a B=3 && goto :end  
if not exist "%~d2\%Recycle%" md "%~d2\%Recycle%"  
vol %~d2 >"%~d2\%Recycle%\%Recycle%.inf"  
exit /b

:Help
echo Stellt einen Papierkorb auf Freigaben ^(ca 25 %% vom freien Speicherplatz^) 
echo zum vorlaeufigen Loeschen zur Verfuegung.
echo(
<nul set /p "=%~n0 " & echo [Freigabe\Name[Pfad][Datei]]  
<nul set /p "=%~n0 " & echo /i Laufwerk  
<nul set /p "=%~n0 " & echo Quelle\%Recycle%\Datei  
echo(& echo  /i Laufwerk	Papierkorb auf externen ^(USB^) Medien Anlegen
 echo   Mit Angabe eines Pfades aus dem Papierkorb wird wiederhergestellt.
 echo   Mit Angabe ohne Pfad wird der Inhalt des Papierkorbes gelistet.
 echo Die Groesse wird an den Verfügbaren Freien Speicherplatz dynamisch angepasst.
 echo Wenn der Papierkorb ca. 25 %% des freien Speicherplatzes der Partition 
 echo ueberschreitet, werden alte Daten bei der Nutzung des Papierkorbes 
 echo gelöscht bis der Wert angeglichen ist.
exit /b

:end
@echo off
setlocal disabledelayedexpansion
 rem CMD-Kontex ?
set "CMDPause=%~f0"  
set "CMDPause=%CMDPause:\=\\%"  
set "CMDPause=%CMDPause:.=\.%"  
setlocal enabledelayedexpansion
for /f delims^= %%i in ("!CMDcmdLine!") do endlocal &set "CMDPin=%%i"  
cmd /von /c "echo !CMDPin!" |findstr /irc:"cmd .*\/c \"\"%CMDPause%\" .*\"" >nul &&endlocal &&set "CMDPause=pause &" ||endlocal &&set "CMDPause="  
if defined CMDPause ping localhost -n %wait% >nul
exit /b %B%

:MoveintTree  Vollstaendige Integration beim verschieben von Ordnern 
:@echo off
setlocal
if "%~1" equ "/?" goto :Help  
if not exist "%~1" goto :Help  
if not exist "%~2" goto :Help  

set "List="  
set "Quiet="  
set "xcopyParam="  
for %%i in (%3 %4 %5 %6) do (if /i "%%~i" equ "/L" set "List=echo"  
  if /i "%%~i" equ "/Q" set "Quiet=%%~i"  
  if /i "%%~i" equ "/U" call set "xcopyParam=%%xcopyParam%%%%~i "  
  if /i "%%~i" equ "/D" call set "xcopyParam=%%xcopyParam%%%%~i "  
)

 rem Verzeichnisse erstellen
if not defined List xcopy %xcopyParam% /TE "%~1\*" "%~2\"  

set /a N=0
 rem Liste abarbeiten
for /f delims^= %%i in ('echo xva^|xcopy %xcopyParam% /LFSE "%~1\*" "%~2\" ^|Find /v "Datei(en) kopiert"') do (  
  set File=%%i
  call :Move
)
echo %N% Datei^(en^) verschoben
if not defined List rd /s "%~1" %Quiet%  
exit /b 0

:Move
set "File=%File: -> =*%"  
for /f "tokens=1,2 delims=*" %%i in ("%File%") do if "%%j" neq "" %List% move "%%~i" "%%~j" >nul && set /a N+=1  
exit /b


:help 
echo Verschiebt den Inhalt der Quelle ins Ziel.
echo Loescht die Quelle auf Nachfrage.
echo(
echo Syntax: %~n0 Quelle Ziel [/L] [/U] [/D] [/Q]
echo(
echo  /L	Zeigt nur das Ergebniss an.
echo  /U	Verschiebt nur Dateien, die im Zielverzeichnis vorhanden sind.
echo  /D	Verschiebt nur Dateien, welche neuer als die im Ziel sind.
echo  /Q	Keine Nachfrage beim Loeschen der Quelle
exit /b