VB Skript startet nicht per Windows 10 Aufgabenplanung

'*******************************************************  
'  
'Download Script zum automatisierten Download des Wärme-  
'pumpenfiles Proclog von Luxtronic WP.Einbinung in Logon  
'Script oder scheduler.  
'  
'coded by Heiko Friedemann 2016 V1.0  
'  
'*******************************************************  
dim UrlWP, strStorePath, UserName 'as String  
dim intDeadLine 'as integer  
dim Dl 'as Boolean  

dim xHttp: Set xHttp = createobject("Microsoft.XMLHTTP")  
dim bStream: Set bStream = createobject("Adodb.Stream")  

'Definition der Variablen  
'Pfad der Wärmepumpe und der Datei  
UrlWP = "http://192.168.1.27/NewProc"  
'Pfad wo die Datei abgelegt werden soll OHNE \ und Dateinamen  
strStorePath = "C:\Users\Stefanseiner\Desktop\Nextcloud\Haus Eppelborn\Infos+Projekte\Heizung\01 - Wärmepumpe\Logs"  
'Zeit nach der die Routine abgebrochen wird in Sekunden (hier 10 Minuten)  
intDeadLine = 600

'Ermittlung des Abbruchzeitpunkts  
TimerCorrection = 0
ForcedTermination = Timer + intDeadLine
if ForcedTermination > 86400 then 'Prüfen ob die Deadline in  
'den nächsten Tag fällt  
ForcedTermination = ForcedTermination - 86400
TimerCorrection = 86400
end if

set objFileSys=CreateObject("Scripting.FileSystemObject")  

'wiederholtes prüfen ob das Ablageverzeichnis da ist,  
'so lange bis es da ist oder die Deadline erreicht ist  
Do
if objFileSys.FolderExists(strStorePath & "\") Then exit do  
if Timer - TimerCorrection > ForcedTermination then
set objFileSys = Nothing
wscript.quit
End If
wscript.sleep (1000)
Loop

Set wsShell = WScript.CreateObject("WScript.Shell")  
UserName = wsShell.ExpandEnvironmentStrings("%USERNAME%")  

'Generieren des Dateinamens für die Ablage  
'im Format ProclogYYYYMMDD.dat  
Dateiname = "Proclog" & DatePart("yyyy", Now) & Right(String(2, "0") & _  
DatePart("m", Now), 2) & Right(String(2, "0") & _  
DatePart("d", Now), 2) & ".dta"  

'Die Schleife wird so lange durchlaufen bis die  
'Logdatei im Ordner ist oder die Deadline erreicht ist.  
Do
If Not objFileSys.FileExists(strStorePath & "\" & Dateiname) Then  
if Timer - TimerCorrection > ForcedTermination then
set objFileSys = Nothing
Set wsShell = Nothing
wscript.quit
End If
'die Wärmepumpendatei wird geöffnet und heruntergeladen  
xHttp.Open "GET", UrlWP, False  
xHttp.Send

'die Ablagedatei wird geöffnet, mit dem Ihnalt  
'der Wärmepumpendatei gefüllt und gespeichert.  
with bStream
.type = 1 '//binary  
.open
.write xHttp.responseBody
'Diese locale Zwischenspeicherung ist um einen Datenverlust  
'beim Verbindungsabbruch bei wackeligen Netzwerken zu vermeiden.  
.savetofile "C:\Users\" & UserName & "\" & Dateiname, 2 '//overwrite  
end with
'Umkopieren der lokalen Datei zum endgültigen Ablageplatz  
objFileSys.MoveFile "C:\Users\" & UserName & "\" & Dateiname, strStorePath & "\"  
dl = true 'die Downloadroutine ist durchlaufen  
wscript.sleep (10000) '10 Sekunden bis zum nächsten Versuch  
else
'wenn die Downloadroutine durchlaufen ist öffnet sich der Explorer mit dem Ablageverzeichnis  
'if dl then wsShell.Run ("Explorer.exe " & strStorePath )  
set objFileSys = Nothing
Set wsShell = Nothing
exit do
End If
Loop