XML Dateien in Verzeichnis auslesen, Prüfung von Datum, Verschieben von XML Datei

Hallo Forengemeinde!,

Ich brauche eine Lösung für mein kleines Problem und bin mit meinen bescheidenen Kenntnissen am Ende....

Ich habe ein Ordner mit folgendem Pfad: D:/ORDNER
In diesem Ordner sind einige XML Dateien.
Ich möchte 2 Werte aus den XML Dateien auslesen:

<ContentTitleText>TITEL</ContentTitleText>

sowie

<ContentKeysNotValidAfter>2012-01-20T00:00:00+01:00</ContentKeysNotValidAfter>

DIese beiden Werte hätte ich gern in eine (TEXT)Datei geschrieben, für jede XML eine Zeile:

TITEL 2012-01-20T00:00:00+01:00
TITEL 2012-01-20T00:00:00+01:00

usw.. Die Werte unterscheiden sich natürlich.

Als Krönung müsste das Script das aktuelle Datum mit dem jeweiligen Datum aus der XML vergleichen (möglichst Sekundengenau) und falls das heutige Datum später ist als der Wert, die XML Datei aus die der Wert stammt in das Verzeichnis D:/ORDNER/alt

verschieben....

Ich bin zu diesem Thema schon auf folgenden Beitrag gestoßen:
Mittels Batch mehrere Einträge aus mehreren XML-Dateien in eine Textdatei schreiben

komme aber nicht wirklich weiter, auch weiß ich nicht ob Powershell oder batch oder wie auch immer am sinnvollsten ist?...

Die Datei möchte ich immer wieder aufrufen, um so ein weiteres füllen der Textdatei(o.ä.) und verschieben der xml dateien zu erwirken.

Ich hoffe das ist nicht unmöglich mit vertretbarem Aufwand?..

Vielen Dank im voraus!

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 178622

Url: https://administrator.de/contentid/178622

Ausgedruckt am: 22.11.2024 um 19:11 Uhr

9 Kommentare

Neuester Kommentar

Hallo Crol1234 und willkommen im Forum!

Soferne der Batch nicht auch die Zeitzone ermitteln soll und die entsprechenden Zeilen in der XML-Datei Deinen Beispielen entsprechen, könnte das so gehen:

@echo off & setlocal
set "Quelle=D:\ORDNER"  
set "Dateien=*.xml"  
set "Ziel=D:\ORDNER\alt"  
set "Log=D:\ORDNER\XML-Log.txt"  

pushd "%Ordner%"  
for /f "delims=" %%i in ('dir /b %Dateien%') do call :ProcessFile "%%i"  
popd
goto :eof

:ProcessFile
for /f "tokens=2 delims=<>" %%a in ('findstr "<ContentTitleText>" %1') do set "Titel=%%a"  
for /f "tokens=2 delims=<>" %%a in ('findstr "<ContentKeysNotValidAfter>" %1') do set "Datum=%%a"  
setlocal enabledelayedexpansion
>>"%Log%" echo %Titel% %Datum%  
endlocal

for /f "tokens=1-3 delims=." %%a in ("%date%") do set "Jetzt=%%c-%%b-%%aT%time:~,8%+01:00"  
set "Jetzt=%Jetzt: =0%"  

if "%Jetzt%" gtr "%Datum%" (  
    md "%Ziel%" 2>nul  
    move %1 "%Ziel%"  
)
goto :eof

Grüße
bastla

[Edit] Noch Vorsorge für ev im Titel enthaltene Sonderzeichen getroffen [/Edit]

Vielen Dank für die super schnelle Möglichkeit!

Ist es unerheblich wo die zwei zu suchenden Parameter sind? Also in welcher Zeile? Ich bin mir nicht sicher ob der Aufbau der XML immer gleich ist. Ich weiß nur dass die zu suchenden Parameter definitiv irgendwo vorhanden sind....

Das mit der Zeitzone hatte ich ganz vergessen... Starke Verkomplizierung?

ok Probleme:

in der Log Datei steht:
ContentTitleText ContentKeysNotValidAfter
ContentTitleText ContentKeysNotValidAfter

aber quasi nicht der Inhalt....

und wenn ich die Batch nochmal ausführe, dann habe ich alle Einträge doppelt... Eine Ergänzung wäre sinnvoll, oder ich lösche die LOG per Hand immer wieder...

[/EDIT] Man könnte ja die Log vor jedem Schreiben erst leeren [/EDIT]

Hallo Crol1234!

Das mit der Zeitzone hatte ich ganz vergessen... Starke Verkomplizierung?

Dafür musste ich noch etwas bei Richard L. Mueller borgen:

@echo off & setlocal
set "Quelle=D:\ORDNER"  
set "Dateien=*.xml"  
set "Ziel=D:\ORDNER\alt"  
set "Log=D:\ORDNER\XML-Log.txt"  

del "%Log%" 2>nul  

set G=%temp%\GetBias.vbs
 >%G% echo 'http://www.rlmueller.net/Programs/Integer8Date.txt  
>>%G% echo lngBiasKey=CreateObject("Wscript.Shell").RegRead("HKLM\System\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias")  
>>%G% echo If (UCase(TypeName(lngBiasKey))="LONG") Then:lngBias=lngBiasKey:Else:If (UCase(TypeName(lngBiasKey))="VARIANT()") Then:lngBias=0:For k=0 To UBound(lngBiasKey):lngBias=lngBias+(lngBiasKey(k)*256^^k):Next  
>>%G% echo lngBias=lngBias/60:S="+":If lngBias^>0 Then S="-"  
>>%G% echo WScript.Echo S^&Right("0"^&Abs(lngBias),2)^&":00"  
for /f %%i in ('cscript //nologo %G%') do set "Bias=%%i"  

pushd "%Ordner%"  
for /f "delims=" %%i in ('dir /b %Dateien%') do call :ProcessFile "%%i"  
popd
goto :eof

:ProcessFile
for /f "tokens=3 delims=<>" %%a in ('findstr "<ContentTitleText>" %1') do set "Titel=%%a"  
for /f "tokens=3 delims=<>" %%a in ('findstr "<ContentKeysNotValidAfter>" %1') do set "Datum=%%a"  
setlocal enabledelayedexpansion 
>>"%Log%" echo %Titel% %Datum%  
endlocal

for /f "tokens=1-3 delims=." %%a in ("%date%") do set "Jetzt=%%c-%%b-%%aT%time:~,8%%Bias%"  
set "Jetzt=%Jetzt: =0%"  

if "%Jetzt%" gtr "%Datum%" (  
    md "%Ziel%" 2>nul  
    move %1 "%Ziel%"  
)
goto :eof

[Edit] Habe Dein "Edit" erst jetzt gesehen ...

Log-File wird gelöscht;
wenn der Logfile-Inhalt

ContentTitleText ContentKeysNotValidAfter
ContentTitleText ContentKeysNotValidAfter

ist, sollte eine Änderung des Tokens auf 3 (ist in dieser Version bereits durchgeführt) genügen - Ursache sind vermutlich Leerzeichen am Beginn der jeweiligen XML-Zeile ...
[/Edit]

Grüße
bastla

Was soll ich sagen, das ist einfach genial!!! Es funktioniert...

Ich danke dir vielmals!!!

ach ganz wichtig:

DIe XML wird niemals verändert? Das ist absolut wichtig!

Kann ich die Ausgabe in die Textdatei noch anders gestalten?

Das Datum ist so noch schlecht lesbar, kann man das in einem anderen Format anzeigen? zB: TT-MM-JJJJ 00:00:00

[EDIT] Mir ist was unglückliches aufgefallen, "alte" Dateien die verschoben werden sollten nicht in dem LOGfile auftauchen [/EDIT]

Hallo Crol1234!

Noch etwas verbessert (es sollten jetzt die Werte immer dann gefunden werden, wenn in der Zeile vor zB "<ContentTitleText>" kein zusätzliches "<" oder ">" enthalten ist):

@echo off & setlocal
set "Quelle=D:\ORDNER"  
set "Dateien=*.xml"  
set "Ziel=D:\ORDNER\alt"  
set "Log=D:\ORDNER\XML-Log.txt"  

del "%Log%" 2>nul  

set G=%temp%\GetBias.vbs
 >%G% echo 'http://www.rlmueller.net/Programs/Integer8Date.txt  
>>%G% echo lngBiasKey=CreateObject("Wscript.Shell").RegRead("HKLM\System\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias")  
>>%G% echo If (UCase(TypeName(lngBiasKey))="LONG") Then:lngBias=lngBiasKey:Else:If (UCase(TypeName(lngBiasKey))="VARIANT()") Then:lngBias=0:For k=0 To UBound(lngBiasKey):lngBias=lngBias+(lngBiasKey(k)*256^^k):Next  
>>%G% echo lngBias=lngBias/60:S="+":If lngBias^>0 Then S="-"  
>>%G% echo WScript.Echo S^&Right("0"^&Abs(lngBias),2)^&":00"  
for /f %%i in ('cscript //nologo %G%') do set "Bias=%%i"  

pushd "%Ordner%"  
for /f "delims=" %%i in ('dir /b %Dateien%') do call :ProcessFile "%%i"  
popd
goto :eof

:ProcessFile
for /f "delims=" %%a in ('findstr "<ContentTitleText>" %1') do set "Zeile=%%a"  
set /a Token=2
if "%Zeile:~,1%" neq "<" set /a Token=3  
for /f "tokens=%Token% delims=<>" %%a in ("%Zeile%") do set "Titel=%%a"  

for /f "delims=" %%a in ('findstr "<ContentKeysNotValidAfter>" %1') do set "Zeile=%%a"  
set /a Token=2
if "%Zeile:~,1%" neq "<" set /a Token=3  
for /f "tokens=%Token% delims=<>" %%a in ("%Zeile%") do set "Datum=%%a"  
for /f "tokens=1-4 delims=T+-" %%a in ("%Datum%") do set "DatumAusgabe=%%c-%%b-%%a %%d"  

for /f "tokens=1-3 delims=." %%a in ("%date%") do set "Jetzt=%%c-%%b-%%aT%time:~,8%%Bias%"  
set "Jetzt=%Jetzt: =0%"  

if "%Jetzt%" gtr "%Datum%" (  
    md "%Ziel%" 2>nul  
    move %1 "%Ziel%"  
) else (
    setlocal enabledelayedexpansion 
    >>"%Log%" echo %Titel% %DatumAusgabe%  
    endlocal
)
goto :eof

DIe XML wird niemals verändert? Das ist absolut wichtig!

Die Datei wird nur gelesen und im Fall des Falles verschoben - der Inhalt bleibt unverändert ...

[Edit] Schreiben in Log vom Alter abhängig gemacht, Datumsausgabe - nochmals um 23:09 - angepasst [Edit2] und in Zeile 32 korrigiert [/Edit2] [/Edit]

Grüße
bastla