Zielgruppenadressierung 64bit oder 32bit - wie macht ihr das?

HI!

Die eingebauten Zeilgruppenadressierungen für GPPs versagen ja bei 32/64bit:
http://support.microsoft.com/kb/2460922
habe hier zwar einen hotfix gefunden, aber muss ich den auf allen Clients installieren?!

http://social.technet.microsoft.com/Forums/de-DE/gruppenrichtliniende/t ...

zu überprüfen ob die Umgebungsvariable Processor_Architecture = "AMD64" ist, hat auch nicht geklappt.
(ist die im Computerteil der GPOs noch nicht verfügbar?)

WMI Abfrage: select * from Win32_OperatingSystem WHERE OSArchitecture = "64-bit"

will auch nicht so.

hat wer einen Tipp - bzw wie macht ihr das?

32 und 64bit OUs will ich eher vermeiden.

ahja wir haben nur Windows 7 Clients - Rest ist egal.

sg Dirm

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 191055

Url: https://administrator.de/forum/zielgruppenadressierung-64bit-oder-32bit-wie-macht-ihr-das-191055.html

Ausgedruckt am: 13.04.2025 um 05:04 Uhr

8 Kommentare

Neuester Kommentar

Moin.
~~Ich würd' den Hotfix runterladen und Ruckzuck per WSUS verteilen.~~
Edit: war Blödsinn.

Sorry, hab gepennt - der Hotfix ist nicht per WSUS verteilbar. Du kannst also nur etwas selbst basteln: wusa.exe kann per Kommando den Hotfix installieren. So könntest Du ein Startskript nutzen, um ihn zu verteilen oder das Kommando in ein MSI verpacken mit WIWW von vins vision.

HI!

okok *gg* ich werde mir das mit den MSIs endlich mal genauer ansehen. hab schon immer wieder getestet und meist mehr Probleme gehabt. (defelte pfade, updates, ...)
sind hier nur 10 User und da zahlt sich nicht alles aus.

sg Dirm

Pack das wusa-Kommando ins Startskript, am einfachsten.

if exist %windir%\adminordner\patchlalala goto :next
md %windir%\adminordner\patchlalala
wusa...
if errorlevel... rd %windir%\adminordner\patchlalala /s /q
:next

wird das jedes mal neu installiert oder prüft er da vorher ob das Packet schon installiert ist?
sg Dirm

Das Skript legt als erstes einen Ordner an, der signalisiert "ich bin schon gelaufen". Beim zweiten Ausführen wird dann geprüft ob der Ordner da ist und wenn ja alles Weitere übersprungen.

ah ok, errorlevel <> 0 prüfen, dann löscht er den Ordner nur wenn ein Fehler aufgetreten ist.
alles klar! danke

sg Dirm

hab ein kleines Skript gebastelt, falls hier jemand auf diesen Thread stößt. Sicher noch ausbaufähig, aber die Grundfunktion ist drinn:

@ECHO OFF
REM Instructions:
REM duplicate Codeblock between START & END and set the three variables:
REM ****** START ******
REM ADMIN_NAME=PATCHNAME (best: KB-Number)
REM ADMIN_FILE_x86=%PATCH_ROOT%\ - PATCHFOLDER - \ - PATCHMSU.msu for 32bit
REM ADMIN_FILE_x64=%PATCH_ROOT%\ - PATCHFOLDER - \ - PATCHMSU.msu for 64bit
REM ****** END ******

REM general paths
SET ADMIN_PATH=%systemroot%\adminfolder
SET PATCH_ROOT=\\fs.domain.local\share
SET WUSA_FLAGS=/quiet /norestart 

IF NOT EXIST %ADMIN_PATH% MD %ADMIN_PATH%

REM get architectur and save to OSARCH
IF %PROCESSOR_ARCHITECTURE% == amd64 (
   SET OSARCH=64
) ELSE (
   SET OSARCH=32 
)

REM ****** START ******
	REM Windows6.1-KB2460922-v2
	SET ADMIN_NAME=Windows6.1-KB2460922-v2
	SET ADMIN_FILE_x86=%PATCH_ROOT%\Windows6.1-KB2460922-v2\Windows6.1-KB2460922-v2-x86.msu
	SET ADMIN_FILE_x64=%PATCH_ROOT%\Windows6.1-KB2460922-v2\Windows6.1-KB2460922-v2-x64.msu

	REM do not change below
	SET ADMIN_PATH_TEMP=%ADMIN_PATH%\%ADMIN_NAME%
	if exist %ADMIN_PATH_TEMP% goto :next 

		md %ADMIN_PATH_TEMP%
		If %OSARCH% == 32 (
			wusa.exe %ADMIN_FILE_x86% %WUSA_FLAGS%
		) ELSE (
			wusa.exe %ADMIN_FILE_x64% %WUSA_FLAGS%
		)

		IF %ERRORLEVEL% == 0 (
			echo %date% %time% installed %OSARCH%bit >> %ADMIN_PATH_TEMP%\%ADMIN_NAME%.log
		) ELSE If %ERRORLEVEL% == 3010 (
			echo %date% %time% reboot required >> %ADMIN_PATH_TEMP%\%ADMIN_NAME%.log
		) ELSE If %ERRORLEVEL% == 2359302 (
			echo %date% %time% allready installed >> %ADMIN_PATH_TEMP%\%ADMIN_NAME%.log
		) ELSE (
			rd %ADMIN_PATH_TEMP% /s /q 
			echo %date% %time% %ADMIN_NAME% error %ERRORLEVEL% >> %ADMIN_PATH%\error.log
		)

	:next
REM ****** END ******

@ECHO ON