Windows Startscript für DialUp-Verbindungen (Modem oder UMTS) zum automatischen Verbinden beim Systemstart

Hallo Gemeinde

Für alle, die ein Startscript fürs Dialup Internet haben wollen, das auch nur arbeitet, wenn Dialup verfügbar ist:
Devcon herunteraden und die exe in system32 schieben, dann folgende Batch-Datei erstellen und eine Verknüpfung dazu in den Autostartordner - die Verknüpfung dann mittels Rechtsklick Eigenschaften minimiert starten lassen.
Die rot markierten Einträge müssen angepasst werden!

@echo off

:: 3 Sekunden Pause, da das Modem beim Systemstart erst initialisiert werden muss.
ping localhost -n 3 >NUL

:: Die Ausgabe von devcon find wird in einer temporäre Datei geleitet.
:: "USB\VID_12D1&PID_1003&MI_00" muss mit der HID des Modems ausgetauscht werden.
:: regedit: HKLM-SYSTEM-CurrentControlSet-Enum-USB
:: Da dann durch die VIDs klicken (auf die jeweiligen Unterschlüssel, bis man den findet,
:: wo etwas mit Modem drin steht, z.B. DeviceDesk "HUAWEI Mobile Connect - 3G Modem".
:: Alternativ den Schlüssel USB öffnen und dann mit Strg+F nach "Modem" suchen
devcon find "USB\VID_12D1&PID_1003&MI_00" >> %temp%\modemabfrage.tmp

:: Der Inhalt der Temp-Datei wird in die Variable eingelesen
for /f "delims== tokens=1" %%i in (%temp%\modemabfrage.tmp) do @set modemabfrage=%%i

:: Die Ausgabe des devcon-Befehls wird verglichen.
:: Falls kein Modem vorhanden ist, wird die Batch beendet.
IF /I "%modemabfrage%"=="No matching devices found." goto ENDE

:: Die temporäre Datei wird gelöscht
del %temp%\modemabfrage.tmp

:: Die Internet-Verbindung wird aufgebaut.
:: "Internet" mit dem Namen der DFÜ-Verbindung austauschen.
rasdial Internet

:: Vereinzelt kommt es vor, dass das UMTS-Netz überlastet ist und ein Verbindungsaufbau fehlschlägt.
:: In diesem Fall wird man mit einem "Fehler-Fenster" darüber benachrichtigt.
IF errorlevel 1 goto FEHLER

:: Ist der Verbindungsaufbau erfolgreich, können noch weitere Programme gestartet werden,
:: die immer benutzt werden, wenn man online geht.
start thunderbird
start D:\Programme\Pidgin\pidgin.exe

:: Da im Falle einer negativen Abfrage gleich zum Ende gesprungen wird, greift der Befehl zum
:: löschen der temporären Datei weiter oben nicht und muss hier nochmal wiederholt werden.
:ENDE
del %temp%\modemabfrage.tmp
exit

:: Die Batch startet ein neues cmd-Fenster mit anderer Farbgebung und gibt einen Hinweistext aus.
:: Da dafür ein "Einzeiler" gebraucht wird, ist der Befehl mit & verkettet.
:FEHLER
start cmd /C "color 7c &echo.& echo Fehler beim Verbindungsaufbau!& echo ------------------------------ & echo.& echo Bitte Verbindung manuell aufbauen:& echo Start - Einstellungen - Netzwerkverbindungen - Internet& echo.& echo Geht das auch nicht, das UMTS-Dongle herausziehen, & echo wieder reinstecken und 10 Sekunden warten.& echo Dann erneut versuchen (s.o.)& echo.& pause"

Gruß Dark