bestimmte Inhalte auslesen

Hallo.


Ich habe ewig probiert, aber leider keine Lösung gefunden.
Nun bitte ich euch um Rat:

Ich habe eine .txt bzw. .doc datei vorliegen. diese beinhaltet
996 seiten. Aus dieser Datei will ich aber nur bestimmte Daten
auslesen.

Hier ein Beispiel:

dokoment1.doc:

[code]Als eigenständiger Begriff[1] [2] wird Haus vor Allem für Gebäude mit Wohnfunktion gebraucht: „Haus ist ein Gebäude, das Menschen zum Wohnen, Unterkunft und Beschäftigung dient.“[1] Umgangssprachlich wird das Wort synonym zu Gebäude – ohne Kontext der Nutzung – verwendet (wie in Hochhaus). Haus wird im Deutschen mit verschiedenen Begriffen zur Bezeichnung unterschiedlicher Gebäudetypen oder dem Verwendungszweck verknüpft, zum Beispiel Wohnhaus, Bauernhaus, Parkhaus, Rathaus, Kaufhaus, Krankenhaus, Waisenhaus, Elefantenhaus, etc.utung auch im Gehäuse.


Teilnehmer-Daten:
Manfred Mustermann
Teststraße 34
99999 Testhausen
0366j 5645646
test@test.de


Das Wort Haus, ursprünglich „Schutz“ (wie Gehäuse), dann „Wohnstatt“ (in hausen), heute „Wohngebäude“ ist schon in den Frühzeiten des Schrifttums auch als Rechtsbegriff üblich.
Das Hausrecht[15] ist ein weltweit übliches Konzept, dass die rechtliche Hoheitsgewalt (die Hausgewalt) über sein Eigentum und Besitz dem Hausherren zusteht, in Unterscheidung zum Kommunalrecht. Das Hausrecht umfasst die Hausgerichtsbarkeit und die Schirmgewalt (das Recht zur Verteidigung). Es ist schon im römischen Recht verankert und findet in der deutschsprachigen Rechtsauffassung auch im germanischen Recht Stütze.


Als eigenständiger Begriff[1] [2] wird Haus vor Allem für Gebäude mit Wohnfunktion gebraucht: „Haus ist ein Gebäude, das Menschen zum Wohnen, Unterkunft und Beschäftigung dient.“[1] Umgangssprachlich wird das Wort synonym zu Gebäude – ohne Kontext der Nutzung – verwendet (wie in Hochhaus). Haus wird im Deutschen mit verschiedenen Begriffen zur Bezeichnung unterschiedlicher Gebäudetypen oder dem Verwendungszweck verknüpft, zum Beispiel Wohnhaus, Bauernhaus, Parkhaus, Rathaus, Kaufhaus, Krankenhaus, Waisenhaus, Elefantenhaus, etc.utung auch im Gehäuse.


Teilnehmer-Daten:
Ursula Mustermann
Testsweg 37
111111 Testdorf
09996 123434
ursula@mustermann.de


Das Wort Haus, ursprünglich „Schutz“ (wie Gehäuse), dann „Wohnstatt“ (in hausen), heute „Wohngebäude“ ist schon in den Frühzeiten des Schrifttums auch als Rechtsbegriff üblich.
Das Hausrecht[15] ist ein weltweit übliches Konzept, dass die rechtliche Hoheitsgewalt (die Hausgewalt) über sein Eigentum und Besitz dem Hausherren zusteht, in Unterscheidung zum Kommunalrecht. Das Hausrecht umfasst die Hausgerichtsbarkeit und die Schirmgewalt (das Recht zur Verteidigung). Es ist schon im römischen Recht verankert und findet in der deutschsprachigen Rechtsauffassung auch im germanischen Recht Stütze.[/code]


Dabei möchte ich nur die Teilnehmer-Daten auslesen.
Vielen Dank für eure Hilfe schon im Voraus.
lg Hannes

@echo off & setlocal
set "Ein=D:\Deine Textdatei.txt"  
set "Aus=D:\Teilnehmer.txt"  

if exist "%Aus%" del "%Aus%"  
set Schreiben=
for /f "tokens=1* delims=:" %%i in ('findstr /n $ "%Ein%"') do set "Zeile=%%j" & call :ProcessLine  
goto :eof

:ProcessLine
echo %Zeile%|findstr /b /i "Teilnehmer-Daten:">nul  
if errorlevel 1 goto :Weiter
set "Schreiben=True" & goto :eof  
:Weiter
if not defined Schreiben goto :eof
if "%Zeile%"=="" set Schreiben=  
>>"%Aus%" echo\%Zeile%  
echo\%Zeile%
goto :eof

@echo off & setlocal
set "Ein=D:\Deine Textdatei.txt"  
set "Aus=D:\Teilnehmer.txt"  

if exist "%Aus%" del "%Aus%"  
set Schreiben=
for /f "tokens=1* delims=:" %%i in ('findstr /n $ "%Ein%"') do set "Zeile=%%j" & call :ProcessLine  
if defined Schreiben >>"%Aus%" echo\%Ausgabe:~1%  
goto :eof

:ProcessLine
echo %Zeile%|findstr /b "Teilnehmer-Daten:">nul  
if errorlevel 1 goto :Weiter
set "Ausgabe=" & set "Schreiben=True" & goto :eof  
:Weiter
if not defined Schreiben goto :eof
if "%Zeile%"=="" (  
    if defined Schreiben (
        >>"%Aus%" echo\%Ausgabe:~1%  
        echo\%Ausgabe:~1%
    )
    set "Schreiben="  
) else set "Ausgabe=%Ausgabe%;%Zeile%"  
goto :eof