Ersten 32 bytes mehrerer binär-dateien mit batch oder vbs löschen

ForceCscript ' Diese Zeile NICHT weglassen, sonst wird die Subroutine ForceCscript nicht aufgerufen ;-)  
SourcePath = "D:\Test"  
SourceExt = "xbt"  
Skip = 32
TargetPath = "D:\Test\Convert"  
TargetExt = "dds"  

Set Fso = CreateObject("Scripting.FileSystemObject")  
If Not Fso.FolderExists(TargetPath) Then Fso.CreateFolder(TargetPath)

For Each File In Fso.GetFolder(SourcePath).Files
    If LCase(Fso.GetExtensionName(File.Name)) = SourceExt Then
        Set BinFileIn = File.OpenAsTextStream
        Set BinFileOut = Fso.CreateTextFile(TargetPath & "\" & Fso.GetBaseName(File.Name) & "." & TargetExt)  
	wscript.echo "Verarbeite: " & File  
        i = 1
        Do Until BinFileIn.AtEndOfStream
            c = BinFileIn.Read(1)
            If i > Skip Then BinFileOut.Write c
            i = i + 1
        Loop
        BinFileIn.Close
        BinFileOut.Close        
    End If
Next
Wscript.Echo "Fertig, zum Fortfahren Enter drücken."  
WScript.StdIn.ReadLine()

Sub ForceCscript
  If (right(Ucase(WScript.FullName),11)="WSCRIPT.EXE") Then  
    Dim WshShell,args,objArgs,I
    Set WshShell = CreateObject("WScript.Shell")  
    WshShell.Run WshShell.ExpandEnvironmentStrings("%COMSPEC%") & _  
    " /C cscript.exe """ & Wscript.ScriptFullName & """" ,1,False  
    Set WshShell = Nothing
   WScript.Quit
  End If
End Sub

Const SourcePath = "D:\Test"  
Const SourceExt = "xbt"  
Const TargetPath = "D:\Test\Convert"  
Const TargetExt = "dds"  

Const Skip = 32
Const adTypeBinary = 1
Const adSaveCreateOverWrite = 2

Dim Fso, File, BinaryStream, ByteArray, NewFile

Set Fso = CreateObject("Scripting.FileSystemObject")  
Set BinaryStream = CreateObject("ADODB.Stream")  

If Not Fso.FolderExists(TargetPath) Then Fso.CreateFolder (TargetPath)

For Each File In Fso.GetFolder(SourcePath).Files
    If LCase(Fso.GetExtensionName(File.Name)) = SourceExt Then

        WScript.Echo "Verarbeite: " & File   
        
        With BinaryStream
            .Type = adTypeBinary
            .Open
            .LoadFromFile File.Path
            .Position = Skip
             ByteArray = .Read(.Size - Skip)
            .Close
        End With
    
        NewFile = TargetPath & "\" & Fso.GetBaseName(File.Name) & "." & TargetExt  
        
        With BinaryStream
            .Type = adTypeBinary
            .Open
            .Write ByteArray
            .SaveToFile NewFile, adSaveCreateOverWrite
            .Close
        End With
    End If
Next

WScript.Echo "Done."  

> cscript //H:cscript //nologo /s
Befehlszeilenoptionen wurden gespeichert.
Der standardmäßige Skripthost ist jetzt "cscript.exe".