EXCEl Externes Programm mit Hyperlink öffnen, am besten noch bestimmten Zellinhalt als Parameter übergeben

Option Explicit
Option Compare Text

Const ColPage = "C"                        'Spalte mit Seitenzahl  
Const BaseFolder = "X:\Temp\Temp1\"        'Backslash am Ende beachten  

Const PdfTool = "X:\Foxitreader\Foxitreader.exe"  
Const PdfOption = " -n "  

Private Sub Worksheet_FollowHyperlink(ByVal Target As Hyperlink)
    Dim sFile As String, sPage As String, sCmdLine As String
        
    sFile = BaseFolder & Range(Target.SubAddress).Value & ".pdf"  
    sPage = Trim(Split(Cells(Target.Range.Row, ColPage).Text, "-")(0))  
    
    With CreateObject("Scripting.FileSystemObject")  
        If .GetExtensionName(sFile) Like "pdf" Then  
            If .FileExists(sFile) Then
                If .FileExists(PdfTool) Then
                    sCmdLine = Chr(34) & PdfTool & """ """ & sFile & Chr(34) & PdfOption & sPage  
                    CreateObject("WScript.Shell").Run sCmdLine, vbMaximizedFocus  
                Else
                    MsgBox "Pdf-Tool nicht gefunden!", vbExclamation, "Fehler . . ."  
                End If
            Else
                MsgBox "Pdf-Datei nicht gefunden!", vbExclamation, "Fehler . . ."  
            End If
        End If
    End With
End Sub

Option Explicit

Const ColLink = "A"                         'Spalte: Titel (Doppelklick)  
Const ColPage = "C"                         'Spalte: Seitenzahl  
Const ColName = "G"                         'Spalte: Pdf-Name  

Const RowStart = 2                          'Pdf-Namen ab Zeile 2  

Const BaseFolder = "X:\Temp\Temp1\"         'Backslash am Ende beachten  

Const PdfTool = "X:\Foxitreader\Foxitreader.exe"  
Const PdfOption = " -n "  

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, ByRef Cancel As Boolean)
    Dim sFile As String, sPage As String, sCmdLine As String
    
    If Not Application.Intersect(Columns(ColLink), Target) Is Nothing Then
        If Target.Row >= RowStart And Cells(Target.Row, ColName).Text <> "" Then  
            Cancel = True
            sFile = BaseFolder & Cells(Target.Row, ColName).Text & ".pdf"  
            sPage = Trim(Split(Cells(Target.Row, ColPage).Text, "-")(0))  
    
            With CreateObject("Scripting.FileSystemObject")  
                If .FileExists(sFile) Then
                    If .FileExists(PdfTool) Then
                        sCmdLine = Chr(34) & PdfTool & """ """ & sFile & Chr(34) & PdfOption & sPage  
                        CreateObject("WScript.Shell").Run sCmdLine, vbMaximizedFocus  
                    Else
                        MsgBox "Pdf-Tool nicht gefunden!", vbExclamation, "Fehler . . ."  
                    End If
                Else
                    MsgBox "Pdf-Datei nicht gefunden!", vbExclamation, "Fehler . . ."  
                End If
            End With
        End If
    End If
End Sub