FolderBrowserDialog - SelectedPath in sichtbaren Bereich anzeigen

#NoTrayIcon
$path = "Desktop|Computer|Daten (D:)|Eigene Bilder"  
$hwnd = WinWaitActive("Ordner suchen",10)  
ControlTreeView($hwnd,"","[CLASS:SysTreeView32; INSTANCE:1]","Select",$path)  
ControlTreeView($hwnd,"","[CLASS:SysTreeView32; INSTANCE:1]","Expand",$path)  

Dim f As New FolderBrowserDialog
With f
    .RootFolder = Environment.SpecialFolder.Desktop
    .SelectedPath = "D:\Bilder"  
    Process.Start("C:\script.exe")  
    .ShowDialog()
End With

Imports System.Runtime.InteropServices

Public Class Form1
    WithEvents tm As New Timer

    Const TV_FIRST As Integer = &H1100
    Const TVGN_ROOT As Integer = &H0
    Const TVGN_NEXT As Integer = &H1
    Const TVGN_CHILD As Integer = &H4
    Const TVGN_FIRSTVISIBLE As Integer = &H5
    Const TVGN_NEXTVISIBLE As Integer = &H6
    Const TVGN_CARET As Integer = &H9
    Const TVM_SELECTITEM As Integer = (TV_FIRST + 11)
    Const TVM_GETNEXTITEM As Integer = (TV_FIRST + 10)
    Const TVM_GETITEM As Integer = (TV_FIRST + 12)
    Const TVM_ENSUREVISIBLE As Long = (TV_FIRST + 20)
    Const TVM_EXPAND As Long = (TV_FIRST + 2)
    Const TVE_EXPAND As Integer = &H2

    <DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Auto)> _  
    Public Shared Function FindWindowEx(ByVal hWndParent As IntPtr, ByVal hWndChildAfter As IntPtr, ByVal lpszClass As String, ByVal lpszWindow As String) As IntPtr
    End Function
    <DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Auto)> _  
    Private Shared Function FindWindow(ByVal lpClassName As String, ByVal lpWindowName As String) As IntPtr
    End Function
    <DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Auto)> _  
    Public Shared Function SendMessage(hWnd As IntPtr, Msg As UInt32, wParam As IntPtr, lParam As IntPtr) As IntPtr
    End Function
    <DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Auto)> _  
    Public Shared Function GetWindowThreadProcessId(hwnd As IntPtr, lpdwProcessId As IntPtr) As IntPtr
    End Function


    Private Sub btnOpenFolderBrowser_Click(sender As System.Object, e As System.EventArgs) Handles btnOpenFolderBrowser.Click
        Dim fBrowser As New FolderBrowserDialog
        tm.Interval = 200
        With fBrowser
            .SelectedPath = "C:\Windows\system32"  
            tm.Start()
            .ShowDialog()
            tm.Stop()
        End With
    End Sub

    Private Sub tm_Tick(sender As Object, e As System.EventArgs) Handles tm.Tick
        'Get TreeView Control on Dialog  
        Dim controlHwnd As IntPtr = getTVHandle(IntPtr.Zero)

        If (controlHwnd <> 0) Then
            'Get selected node  
            Dim selectedNode As IntPtr = SendMessage(controlHwnd, TVM_GETNEXTITEM, TVGN_CARET, IntPtr.Zero)
            'scroll selected item into view  
            SendMessage(controlHwnd, TVM_ENSUREVISIBLE, IntPtr.Zero, selectedNode)
            'expand node  
            SendMessage(controlHwnd, TVM_EXPAND, TVE_EXPAND, selectedNode)
            'stop timer  
            tm.Stop()
        End If
    End Sub

    Function getTVHandle(handle As IntPtr) As IntPtr
        Dim parent As IntPtr, returnTVHandle As Boolean
        If handle = IntPtr.Zero Then
            parent = FindWindow("#32770", Nothing)  
            If Not isFromSameThread(parent) Then
                Return getTVHandle(parent)
            Else
                returnTVHandle = True
            End If
        Else
            parent = FindWindowEx(IntPtr.Zero, handle, "#32770", Nothing)  
            If Not isFromSameThread(parent) Then
                Return getTVHandle(parent)
            Else
                returnTVHandle = True
            End If
        End If
        If returnTVHandle Then
            'Get Control handle  
            Dim subWin As IntPtr = FindWindowEx(parent, IntPtr.Zero, "SHBrowseForFolder ShellNameSpace Control", Nothing)  
            Dim controlHwnd As IntPtr = FindWindowEx(subWin, IntPtr.Zero, "SysTreeView32", Nothing)  
            Return controlHwnd
        End If
    End Function

    Function isFromSameThread(handle As IntPtr) As Boolean
        Dim cID As Integer = AppDomain.GetCurrentThreadId()
        Dim fID As Integer = GetWindowThreadProcessId(handle, IntPtr.Zero)
        Return (cID = fID)
    End Function
End Class