In mehrzeiliger Textdatei verschiedene Zeilen auslesen und in Variablen aufsplitten

Hallo Forum,

ich möchte per Batch Datenreihen aus einer Textdatei verwerten.

Hintergrund:

Es sollen IP-Einträge gesetzt werden, die für verschiedene Rechner in einer textdatei vordefiniert werden.
Beispiel:

Settings.txt
PC1 | 192.168.10.10 | 192.168.10.1 | 255.255.255.192 | etc....
PC2 | 192.168.10.11 | 192.168.10.1 | 255.255.255.192 | etc....
PC3 | 192.168.10.12 | 192.168.10.1 | 255.255.255.192 | etc....
PC4 | 192.168.10.13 | 192.168.10.1 | 255.255.255.192 | etc....

Ich will nun den Benutzer der Datei (Administratorrechte vorhanden) auffordern, die Kennung des PCs einzugeben.
Die Batch soll nun in der Settings.txt zu der Zeile springen, in der beispielsweise "PC2" steht. Nun sollen die
einzelnen Columns als Variablen in die entsprechend definierten Stellen in der Batch eingefügt werden. Also so:

IP-Adresse soll sein IP
Subnetzadresse soll sein SN
Gateway soll sein GW
etc...

netsh interface ipv4 set address "LAN-Verbindung" static %IP% %SN% %GW% 1

Mein Problem ist nun, wie kann ich erreichen, dass die einzelnen Columns so definiert werden, wie ich sie brauche?
Mir fehlt da komplett der Ansatz...

Also
1. Wie springe ich in die entsprechende Zeile der Datei "Settings.txt", die der User vorgibt und
2. wie definiere ich die Columns so, dass eben bei IP die IP-Adresse, bei SN die Subnetz-Adresse etc. übergeben wird?

Schon mal vielen Dank für Eure Hilfe!

@echo off & setlocal

set /p "CompName="  
echo.

set "SettingsFile=.\settings.txt"  
set "Found="  
set "IP="  
set "SN="  
set "GW="  

for /f "tokens=2-4 delims=|" %%a in ('findstr /i /b /c:"%CompName%" "%SettingsFile%"') do (  
  set "Found=1"  
  for /f %%A in ("%%a") do set "IP=%%A"  
  for /f %%A in ("%%c") do set "SN=%%A"  
  for /f %%A in ("%%b") do set "GW=%%A"  
)

if defined Found (
  echo IP:      %IP%
  echo Subnet:  %SN%
  echo Gateway: %GW%
  echo.
) else (
  echo PC-Name ist unbekannt.
  echo.
)