LDAP Suche in verschiedenen OUs

Const sZDatei = "Signatur.txt"  
Set fso = CreateObject("Scripting.FileSystemObject")  
Set objShell = CreateObject("Wscript.Shell")  

strUsername = objShell.ExpandEnvironmentStrings("%username%")  
set objUser = FindAccount(strUsername)
if not objUser is nothing then
	Set oZDatei = fso.OpenTextFile(sZDatei, 2, True)
	oZDatei.Write "Mit freundlichen Grüßen" & vbCrLf & vbCrLf & vbCrLf  
	oZDatei.Write objUser.givenname &" " & objUser.sn & vbCrLf & vbCrLf  
	oZDatei.Write objUser.department & vbCrLf & vbCrLf
	oZDatei.Write objUser.street & vbCrLf
	oZDatei.Write objUser.postalcode &" " & objUser.l & vbCrLf & vbCrLf  
	oZDatei.Write "Tel.: " & objUser.telephonenumber & vbCrLf  
	oZDatei.Write "Mail: " & objUser.mail & vbCrLf  
	oZDatei.Close
Else
	' Kein User mit diesem Loginnamen gefunden'  
End if

Function FindAccount(strUserName)
	On Error Resume Next
	Dim adoCommand, adoConnection
	Dim varBaseDN, varFilter
	Dim objRootDSE, varDNSDomain, strQuery, adoRecordset

	Set adoCommand = CreateObject("ADODB.Command")  
	Set adoConnection = CreateObject("ADODB.Connection")  
	adoConnection.Provider = "ADsDSOObject"  
	adoConnection.Open "Active Directory Provider"  
	Set adoCommand.ActiveConnection = adoConnection
	
	' Search entire Active Directory domain.  
	Set objRootDSE = GetObject("LDAP://RootDSE")  
	
	varDNSDomain = objRootDSE.Get("defaultNamingContext")  
	varBaseDN = "<LDAP://" & varDNSDomain & ">"  
	
	' Filter for user objects.  
	varFilter = "(&(objectCategory=person)(objectClass=user)(SamAccountName=" & strUserName & "))"  
	
	' Construct the LDAP syntax query.  
	adoCommand.CommandText = varBaseDN & ";" & varFilter & ";ADSPath;Subtree"  
	adoCommand.Properties("Page Size") = 2  
	adoCommand.Properties("Timeout") = 20  
	adoCommand.Properties("Cache Results") = False  
	Set adoRecordset = adoCommand.Execute
	adoRecordset.MoveFirst

	If adoRecordset.RecordCount > 0 Then
		set FindAccount = GetObject(adoRecordset("ADSPath"))  
	else
		set FindAccount = Nothing
	End If
	
	adoRecordset.Close
	adoConnection.Close
End Function