Mit Batch Variablen aus Datei lesen, Ordner erstellen und in neue Datei schreiben

Hallo Miteinander!

Ich habe mehrere digitale Bilderrahmen welche verschiedenen Bildersets mit einer Beschreibung anzeigen. Die Bilder sind alle jpg´s und die Beschreibung wird in einer einfachen Textdatei (bilderset.userdata) abgelegt. Die Textdatei liegt zusammen mit den Bildern und 2 anderen Config Dateien in einem Ordner. Pro Bilderset gibt es einen Ordner mit dem Namen des Bildersets.

Leider ist die mitgelieferte Software zum Verwalten der Bilderordner fehlerhaft und total umständlich zu bedienen und da es die Firma (LIBpixel) nicht mehr gibt sind auch keine Updates zu erwarten. Da ich aber 5 von den Bilderrahmen besitze und die Qualität recht ordentlich ist würde ich diese gerne weiter benutzen.

Die config Dateien sind recht einfach aufgebaut, bisher habe ich diese selber von Hand erstellt, was beim Befüllen / Tauschen der Bilder aber immer mehrere Stunden in Anspruch nimmt. Da ich die Daten schon in einer Datei liegen habe bzw. exportieren kann, wollte ich versuchen dies per Batch zu automatisieren.

Da ich aber eher aus der Fotographen / Bildbearbeitungsecke komme wollte ich fragen ob mir evtl. jemand etwas behilflich sein kann bzw. in die richtige Richtung lenken kann. Ich habe es bisher nur geschafft immer den ersten Eintrag auszulesen, ich vermute ich benötige eine For Schleife, verstehe aber nicht genau wie ich diese benutze.

In der Datei content.userdata sind die einzelnen Bildersets abgelegt (siehe unten) jedes Bilderset beginnt mit [bilderset] und hat die Variablen „beschreibung, name, schluesselwort und machmal noch weitere welche aber nicht benötigt werden“.
Aus der Variable „Beschreibung“ soll für jedes Bilderset ein Ordner erstellt werden.

In den Ordner wird dann die Datei „bilderset.userdata“ erstellt (siehe weiter unten) welche die Variablen „Name, Schluesselwort“ und 4 weitere variablen enthält die aber für alle Bildersets gleich sind.

Bin für jede Hilfe dankbar!

Schönen Sonntag noch!

Gruß Tendi

Inhalt Auszulesende Datei (content.userdata):

#Blablabla
#Blablabla
#Blablabla

[bilderset]				//Eckige Klammern stehen auch so in Datei
beschreibung	= Beschreibung	1	//Für jedes Bilderset vorhanden bzw. auszulesen
name		= name1			//Für jedes Bilderset vorhanden bzw. auszulesen
schluesselwort	= schluesselwort1	//Für jedes Bilderset vorhanden bzw. auszulesen

[bilderset]				//Eckige Klammern stehen auch so in Datei
beschreibung	= Beschreibung	2	//Für jedes Bilderset vorhanden bzw. auszulesen
name		= name2			//Für jedes Bilderset vorhanden bzw. auszulesen
schluesselwort	= schluesselwort2	//Für jedes Bilderset vorhanden bzw. auszulesen
variable1a	= paramter1a		//Für manche Sets vorhanden NICHT auslesen
variable1b	= paramter1b		//Für manche Sets vorhanden NICHT auslesen

[bilderset]				//Eckige Klammern stehen auch so in Datei
beschreibung	= Beschreibung	3	//Für jedes Bilderset vorhanden bzw. auszulesen
name		= name3			//Für jedes Bilderset vorhanden bzw. auszulesen
schluesselwort	= schluesselwort3	//Für jedes Bilderset vorhanden bzw. auszulesen
variable1a	= paramter1a		//Für manche Sets vorhanden NICHT auslesen

[bilderset]
beschreibung	= Beschreibung	4
…

Zu erstellende Ordnerstruktur:

Ordner[ XYZ]
	I
	I------- Ordner [Beschreibung1]
	I		I
	I		I-------Datei [bilderset.userdata]      // siehe Beschreibung unten
	I		I
	I		I-------Datei [bilderset.xyz]		// Immer gleich wird einfach kopiert
	I		I
	I		I-------Datei […]			// Immer gleich wird einfach kopiert
	I
	I
	I------- Ordner [Beschreibung2]
	I		I
	I		I-------Datei [bilderset.userdata]	// siehe Beschreibung unten
	I		I
	I		I-------Datei [bilderset.xyz]		// Immer gleich wird einfach kopiert
	I		I
	I		I-------Datei […]			// Immer gleich wird einfach kopiert
	I
	I
	I------- Ordner [Beschreibung3]
	I		I
	I		I-------Datei [bilderset.userdata]	// siehe Beschreibung unten
	I		I
	I		I-------Datei [bilderset.xyz]		// Immer gleich wird einfach kopiert
	I		I
	I		I-------Datei […]			// Immer gleich wird einfach kopiert
	I
	I
	I------- Ordner [Beschreibung4]
	I		I
	I		I…
	I…

Zu erstellende Datei bilderset.userdata (für jeden Ordner [BeschreibungX] unterschiedlich).

[bilderset]					// Eckige Klammern sollen auch so in der Datei stehen
bildname	= bildnameX(1,2,3…)	        // Name aus Datei ausgelesen
bildschluessel	= schluesselwortX(1,2,3…)	// Schluesselwort aus Datei ausgelesen
config1		= wert1				// Für alle Sets gleich
config2		= wert2				// Für alle Sets gleich
config3		= wert3				// Für alle Sets gleich

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 186221

Url: https://administrator.de/forum/mit-batch-variablen-aus-datei-lesen-ordner-erstellen-und-in-neue-datei-schreiben-186221.html

Ausgedruckt am: 27.12.2024 um 08:12 Uhr

2 Kommentare

Neuester Kommentar

Hallo tendax.

Probier mal was in der Art:

@echo off &setlocal
set "source=content.userdata"  
set "copyMe=bilderset.xyz"  
set "createMe=bilderset.userdata"  
set "config1=Wert1"  
set "config2=Wert2"  
set "config3=Wert3"  

set "beschreibung=" &set "name=" &set "schluesselwort=" &set "start="  

for /f "usebackq tokens=1,* delims==	 " %%i in ("%source%") do (  
  if "%%i"=="[bilderset]" (  
    set "beschreibung=" &set "name=" &set "schluesselwort=" &set "start=1"  
  )
  if defined start (
    if "%%i"=="beschreibung" set "beschreibung=%%j"  
    if "%%i"=="name" set "name=%%j"  
    if "%%i"=="schluesselwort" set "schluesselwort=%%j"  
    if defined beschreibung if defined name if defined schluesselwort (
      setlocal EnableDelayedExpansion
        md "!beschreibung!"  
        copy "!copyMe!" "!beschreibung!\"  
        >"!beschreibung!\!createMe!" echo [bilderset]  
        >>"!beschreibung!\!createMe!" echo bildname	= !name!  
        >>"!beschreibung!\!createMe!" echo bildschluessel	= !schluesselwort!  
        >>"!beschreibung!\!createMe!" echo config1		= !config1!  
        >>"!beschreibung!\!createMe!" echo config2		= !config2!  
        >>"!beschreibung!\!createMe!" echo config3		= !config3!  
      endlocal
      set "start="  
    )
  )
)

Natürlich darf in der Beschreibung kein Zeichen vorkommen, dass nicht in Verzeichnisnamen verwendet werden darf.
Datei bilderset.xyz soll ja kopiert werden - müsste also auch vorher schon existieren.

Grüße
rubberman

moin tendax,

für einen Batch gestartet aus dem Ordner der Dilderset in etwa so:

@echo off
setlocal disabledelayedexpansion

set "InputFile=bilderset.userdata"  
set "copy1=XYZ"  

for /f "usebackq tokens=1* delims== 	" %%i in ("%inputFile%") do (set "%%i=%%j"  
  if "%%i" equ "name" md "%%j" 2>nul &pushD "%%i"  
  if "%%i" equ "schluesselwort" >bilderset.userdata (  
    setlocal enabledelayedexpansion
    echo [bilderset]
    echo bildname	= !name!
    echo bildschluessel	= !schluesselwort!
    echo config1		= wert1
    echo config2		= wert2
    echo config3		= wert3
    endlocal
    copy "%copy1%"  
  ) &&popD
)