Mit for Schleife Dateien in Unterverzeichnissen vergleichen

Hallo

Ich muss doch nochmal um Hilfe bitten.

Ich möchte mit einer for-Schleife Dateien in Unterverzeichnissen vergleichen.
Ich habe es wie folgt und in mehreren Abwandlungen probiert

for /R j:\DATASAVE\%DATE%\ %%i in ("*.*") do @FC "%i" "e:\%DATE%\%%~pnxi"

Es werden jedesmal die Dateien in den Unterverzeichnissen von e: nicht gefunden. Subst von j:\DATASAVE brachte kaum Verbesserung. E: ist eine DVD-RAM und J:\DATASAVE das Ursprungsverzeichnis von dem auf DVD per xcopy kopiert wurde.

Leider kann ich kaum noch experimentieren, da ich den Rechner gestern "scharf" gemacht habe, also in das Netz integriert.
Bräuchte diesmal also die perfekte Syntax.

flic

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 41152

Url: https://administrator.de/contentid/41152

Ausgedruckt am: 16.11.2024 um 05:11 Uhr

4 Kommentare

Neuester Kommentar

Moin flicflac,

wie der Zufall so spielt, habe ich gestern folgendes gepostet:

::----snipp QuickNDirtyDirComp.bat [Param1: VerzeichnisA Param2: VerzeichnisB]
@echo off 
for  %%i in ("%1\*.*") do (  
    if not exist "%2\%%~nxi" (  
       echo [in Verz 2:] "%2\%%~nxi" nicht vorhanden.  
    ) ELSE (  
       fc "%%i" "%2\%%~nxi">nul|| echo Dateien "%%~nxi" sind unterschiedlich.  
))
for  %%i in ("%2\*.*") do if not exist "%1\%%~nxi" echo [in Verz 1:] "%1\%%~nxi" nicht vorhanden.  

Details siehe Batch-Datei Verzeichnisse vergleichen.

Ob es die perfekte Syntax ist, weiß ich nicht, war eher schnell zusammengeschrotet..

Da Deine Parameter noch Leerzeichen in Verzeichnisnamen haben können (%date%), noch folgende Anpassung:

::----snipp QuickNDirtyDirComp.bat [Param1: VerzeichnisA Param2: VerzeichnisB]
@echo off 
for  %%i in ("%~1\*.*") do (  
    if not exist "%~2\%%~nxi" (  
       echo [in Verz 2:] "%~2\%%~nxi" nicht vorhanden.  
    ) ELSE (  
       fc "%%i" "%~2\%%~nxi">nul|| echo Dateien "%%~nxi" sind unterschiedlich.  
))
for  %%i in ("%~2\*.*") do if not exist "%~1\%%~nxi" echo [in Verz 1:] "%~1\%%~nxi" nicht vorhanden.  

Gruß
Biber

So, flicflac,

nochmal eine Annäherung an die Lösung -mit nochmal drei Zeilen mehr für das rekursive Abarbeiten der Verzeichnisstruktur...

::-----------snipp qndDirCompRekursiv.bat Biber 2006 with a smile... for Educational Purposes
@echo off & setlocal enabledelayedExpansion
for /r "%~s1" %%y in (.) do set "subdir=%%~sdpnxy" & call:ProcessSubDir %~s1!subdir:%~s1=! %~s2!subdir:%~s1=!  
goto :eof
:ProcessSubDir Param1:quellDir[richtige Ebene] Param2: Zieldir[richtige Ebene]
echo [--- Verz 1: %1 --------  Verz 2 %2  ------] 
for  %%i in ("%1\*.*") do (  
    if not exist "%2\%%~nxi" (  
       echo [in Verz 2:] "%2\%%~nxi" nicht vorhanden.  
    ) ELSE (  
       fc "%%i" "%2\%%~nxi">nul|| echo Dateien "%%~nxi" sind unterschiedlich.  
))
for  %%i in ("%2\*.*") do if not exist "%1\%%~nxi" echo [in Verz 1:] "%1\%%~nxi" nicht vorhanden.  
goto :eof
:: ------ -----------snipp qndDirCompRekursiv.bat

Diese Skizze würde dann auch die Verzeichnisstrukturen von Originalverzeichnis und Kopieverzeichnis parallel durchlaufen....

so wie Du es mir der FOR /R-Schleife ja vorhattest.

Output wäre bei mir [zwei Parameter OriginalDir und CloneDir MUSST Du mitgeben - keine Parameterprüfung!]:

>qndDirCompRekursiv.bat d:\temp\templogs d:\temp\$home\logs
[--- Verz 1: d:\temp\templogs --------  Verz 2 d:\temp\$home\logs  ------]
Dateien "2006-09-28.log" sind unterschiedlich.  
Dateien "log.txt" sind unterschiedlich.  
[in Verz 2:] "d:\temp\$home\logs\temp.txt" nicht vorhanden.  
[in Verz 1:] "d:\temp\templogs\2005logs.txt" nicht vorhanden.  
[in Verz 1:] "d:\temp\templogs\2006-07-03.log" nicht vorhanden.  
[--- Verz 1: d:\temp\templogs\2004 --------  Verz 2 d:\temp\$home\logs\2004  ------]
[--- Verz 1: d:\temp\templogs\2005 --------  Verz 2 d:\temp\$home\logs\2005  ------]
[in Verz 2:] "d:\temp\$home\logs\2005\2005logs.txt" nicht vorhanden.  
[--- Verz 1: d:\temp\templogs\2006 --------  Verz 2 d:\temp\$home\logs\2006  ------]
[in Verz 2:] "d:\temp\$home\logs\2006\2006-07-03.log" nicht vorhanden.  
[--- Verz 1: d:\temp\templogs\2009 --------  Verz 2 d:\temp\$home\logs\2009  ------]
[in Verz 2:] "d:\temp\$home\logs\2009\2009bla.bla" nicht vorhanden.  
[--- Verz 1: d:\temp\templogs\2010 --------  Verz 2 d:\temp\$home\logs\2010  ------]
[--- Verz 1: d:\temp\templogs\2010\april --------  Verz 2 d:\temp\$home\logs\2010\april  ------]
[in Verz 2:] "d:\temp\$home\logs\2010\april\april.fil" nicht vorhanden.  

...works as designed...

Geht bestimmt auch kürzer, aber ich dachte, damit kannst du erstmal loslaufen.
Falls Du inzwischen eine andere Variante ausgetüftelt hast, bitte posten. Danke.

Schönes Wochenende.

Biber

Moin flicflac,

konntest Du etwas damit anfangen oder wie ist der Status dieses Threads?

Grüße
Biber

Hallo Biber

THX erstmal.

Meine ersten Versuche schlugen fehl.
Ich kann derzeit nur per Fernwartung an den PC. Durch den langsamen Bildaufbau erkennt man kaum was. Ich teste das Mitte nächster Woche auf einem anderen PC.

Thread also bitte noch offen lassen.

PS: Dauert noch bis 1.Novemberwoche

Frage Entwicklung Batch, Shell

Mehr von flicflac

Automatisches Login am Novell-Serverflicflac - 2 Kommentare

Ghost 9 Image reparierenflicflac - 2 Kommentare

APC powerchute für Netware 4.11flicflac

DVD-RAM Rohlinge und Laufwerk mit perfekter Kompatiblitätflicflac

Heiß diskutiert