Multi-Page Tiff mit Powershell erstellen

function initCode() {
    [String]$SourceCode = @"  
Imports System
Imports System.Drawing
Imports System.Drawing.Imaging
Imports System.Text.RegularExpressions
Imports System.IO

Namespace colinardo
Public Class tiff
    Public Shared Function mergeTiff(bitmaps() As String, outPath As String) As String
        Dim enc As Encoder = Encoder.SaveFlag
        Dim info As ImageCodecInfo = Nothing
        For Each ice As ImageCodecInfo In ImageCodecInfo.GetImageEncoders()
            If ice.MimeType = "image/tiff" Then  
                info = ice
            End If
        Next
        Dim ep As EncoderParameters = New EncoderParameters(1)
        ep.Param(0) = New EncoderParameter(enc, EncoderValue.MultiFrame)
        Dim pages As System.Drawing.Bitmap = Nothing
        Dim regex As New Regex("bmp|jpg|jpeg|gif|tif|tiff|png", RegexOptions.IgnoreCase)  
        For i As Integer = 0 To bitmaps.Length - 1
            If Not regex.IsMatch(Path.GetExtension(bitmaps(i).ToLower())) Then
                Return "Fehler! Ein Bild enthält ein ungültiges Format, erlaubte Formate sind bmp|jpg|jpeg|gif|tif|tiff|png"  
            End If
        Next
        For i As Integer = 0 To bitmaps.Length - 1
            Try
                If i = 0 Then
                    pages = System.Drawing.Image.FromFile(bitmaps(i))
                    pages.Save(outPath, info, ep)
                Else
                    Dim b As Bitmap = Image.FromFile(bitmaps(i))
                    ep.Param(0) = New EncoderParameter(enc, EncoderValue.FrameDimensionPage)
                    pages.SaveAdd(b, ep)
                    b.Dispose()
                End If
                If i = bitmaps.Length - 1 Then
                    ep.Param(0) = New EncoderParameter(enc, EncoderValue.Flush)
                    pages.SaveAdd(ep)
                    pages.Dispose()
                End If
            Catch ex As Exception
                Return "Fehler : " & ex.Message  
            End Try
        Next
        Return "OK"  
    End Function
End Class
End Namespace
"@  
 add-type -TypeDefinition $SourceCode -Language VisualBasic -ReferencedAssemblies System.Drawing
}
initCode
$images = @("D:\Bild1.tiff", "D:\Bild2.tiff", "D:\Bild3.tiff")  
$mergeImage ="D:\merge.tif"  
[colinardo.tiff]::mergeTiff($images,$mergeImage)
# garbage collection starten / Resourcen freigeben
[GC]::Collect()

add-type -TypeDefinition $SourceCode -Language VisualBasic -ReferencedAssemblies System.Drawing -OutputType Library -OutputAssembly "C:\PfadzurDll\tiff.dll"

add-type -Path "C:\PfadzurDll\tiff.dll"  

[GC]::Collect()