16.02.2007, aktualisiert am 03.01.2008

6677

Ordner in Unterordner des Mainordners automatisch erstellen. Wie ?

Hallo ihr alle,

ich habe mal ne Frage.

Wie kann ich es machen, dass ich in alle meine Unterordner von "TEST" einen Ordner namens "XY" erstell?

Dann fänd ich es noch gut, wenn es eine Lösung gibt welches folgende Dinge "ausführt".

1) Suche in Unterordner von TEST ( allen Ordnern der nächsten Ebene nicht tiefer) nach einem Ordner "Jahr x" (muss variabel sein)
2)Wenn nicht vorhanden erstellen
3)Verschiebe alle welche im Jahr x erstellt wurden in den Ordner "Jahr x"

Kann mir dazu jemand vielleicht helfen?

MfG Sandro

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 51867

Url: https://administrator.de/contentid/51867

Ausgedruckt am: 22.11.2024 um 14:11 Uhr

8 Kommentare

Neuester Kommentar

Moin Saggi,

ich habe jetz mal als "Jahr x" das Jahr 2006 eingesetzt.

Demo zu 1+2) Am CMD-Prompt:

for /D %i in (\TEST\*) do @<b>ECHO</b> if not exist "%~nxi\Jahr 2006" md "%~nxi\Jahr 2006"  
for /D %i in (\TEST\*) do @for %j in ("\TEST\%~nxi\*.xls") do @echo %~tj|find ".2006">nul && @<b>ECHO</b> Move "%i\%j" "%i\Jahr 2006\*.*"  

In den beiden Zeilen muss das fette ECHO nach dem Anpassen und Testen entfernt werden.
Im Batch dann ggf. zwei Prozentzeichen statt einem vor den dynamischen Variablen (%%i statt %i etc.).

HTH
Biber

Hallo,

danke für deine Antwort.

Habe allerding ein Problem damit.
Dein Code findet alle Ordner, es verschiebt aber keine Dateien sondern zeigt mir nur auf dem Bildschrim an, was er gerade macht, also welche Dateien er angeblich verschiebt.

Kannst du mir vielleicht nochmals helfen?

MfG
Sandro

Moin Saggi

Siehe oben:

In den beiden Zeilen muss das fette ECHO nach dem Anpassen und Testen entfernt werden.

Die "produktive" Variante z.B. der ersten Zeile ware dann
- statt im TEST

for /D %i in (\TEST\*) do @echo if not exist "%~nxi\Jahr 2006" md "%~nxi\Jahr 2006"

- neu im Einsatz/in PROD:

for /D %i in (\TEST\*) do @if not exist "%~nxi\Jahr 2006" md "%~nxi\Jahr 2006"

Zweite Zeile entsprechend.

Gruß
Biber

Moin Saggi

Siehe oben:
> In den beiden Zeilen muss das fette
ECHO nach dem Anpassen und Testen entfernt
werden.

Die "produktive" Variante z.B. der
ersten Zeile ware dann
- statt im TEST
> for /D %i in (\TEST\*) do @echo if not
exist "%~nxi\Jahr 2006" md
"%~nxi\Jahr 2006"
- neu im Einsatz/in PROD:
> for /D %i in (\TEST\*) do @if not exist
"%~nxi\Jahr 2006" md
"%~nxi\Jahr 2006"

Zweite Zeile entsprechend.

Gruß
Biber

Hallo,

danke für deine erneute Hilfe, aber das ganze funktioniert leider noch nicht.
Wenn ich das Echo stehen lass, listet er mir alles so, wie es auch geschehen soll.
Entfern ich dann aber das Echo, dann passiert rein garnichts mehr.
Das "Dos-Fenster" öffnet sich kurz und schließt sich ohne Aktion sofort wieder.

Was kann denn da der Fehler sein?

MfG Sandro

Es gibt einen Hauptordner
In diesem gibt es Unterordner
In den Unterordnern wird jeweils ein Order "Jahr 200$x" erstellt
Alle Dateien und Ordner im Unterordner sollen in den Ordner "Jahr
200$x" verschoben werden AUSNAHME Ordner mit dem Namen Jahr 200$x - diese
sollen bleiben.

Es gibt keinen bestimmten Dateityp - es soll alles verschoben werden.

Der bisherige Ansatz war:

[code]for /D %i in (\TEST\*) do @for %j in ("\TEST\%~nxi\*.xls") do
@echo %~tj|find ".2006">nul && @echo
Move "%i\%j" [/code]

Wäre sehr nett wenn du mir nochmals helfen könntest.

MfG Sandro

Moin Saggi,

Es gibt einen Hauptordner
In diesem gibt es Unterordner
In den Unterordnern wird jeweils ein Order "Jahr 200$x" erstellt

Also nennen wir die oberen Ebenen mal "x:\Hauptordner" und "UnterordnerA" [.und parallel UnterOrdnerB.."

Alle Dateien und Ordner im Unterordner sollen in den Ordner "Jahr 200$x" verschoben werden
AUSNAHME Ordner mit dem Namen Jahr 200$x - diese sollen bleiben.

Okay, wenn also ein Verzeichnis "HauptOrdner" existiert mit "UnterordnerA", "UnterOrdnerB"...
Dann laufe ich diese Struktur entlang mit [Test am CMD-Prompt]:

for /D %i in ("x:\HauptOrdner\*") do @echo %i  

Hier sollte Dir jetzt so etwas angezeigt werden:

x:\HauptOrdner\Hund
x:\HauptOrdner\Katze
x:\HauptOrdner\Maus
x:\HauptOrdner\UnterordnerA
x:\HauptOrdner\UnterordnerB
...

Wenn das klappt, dann eine Ebene tiefer gehen (eine weitere FOR/D-Anweisung dahintersetzen:

for /D %i in ("x:\HauptOrdner\*") do @for /D %j in ( "%i\*") do @echo %j  

Jetzt sollte etwas in der Art zu sehen sein:

x:\HauptOrdner\Hund\Futter
x:\HauptOrdner\Hund\Steuer
x:\HauptOrdner\Hund\Tierarzt
x:\HauptOrdner\Hund\Jahr 2006
x:\HauptOrdner\Katze\Streu
x:\HauptOrdner\Katze\Möbel
x:\HauptOrdner\Katze\Jahr2006
....
....
x:\HauptOrdner\Maus
...
x:\HauptOrdner\Maus\Jahr 2006

x:\HauptOrdner\UnterordnerA
...
x:\HauptOrdner\UnterordnerB
...

Wenn num alle Verzeichnisse unterhalb der Ebenen Hund/Katze/Maus außer dem "Jahr 2006" selbst verschoben werden sollen, dann
(Fast der letzte) Test am CMD-Prompt:

for /D %i in ("x:\HauptOrdner\*") do @for /D %j in ( "%i\*") do @echo "%~nxj"|find /v "Jahr 2006"  

Jetzt sollten nur alle Ordner angezeigt werden, die NICHT "Jahr 2006" heißen.
Und diese verschieben wir -wenn das bisher geklappt hat!-
Jetzt als Batch-Version - alle Prozentzeichen werden verdoppelt:

::----das wird ein Batch.cmd
@echo off

for /D %%i in ("x:\HauptOrdner\*") do @for /D %%j in ( "%%i\*") do @(  
        echo "%%~nxj"|find /v "Jahr 2006" >nul && move "%%j" "%%i\Jahr 2006"  
       ) 

Das einzige, was dazugekommen ist:

&& move "%%j" "%%i\Jahr 2006"

...übersetzt soviel wie :
wenn Du mit den Befehl vorher, also Find /v ERFOLGREICH warst, kein Verzeichnis "Jahr 2006" gerade gefunden hast, dann verschieb dieses Verzeichnis.

Probier mal bitte mit Deinen Werten für "x:\HauptOrdner" und "UnterOrdner" aus, inwieweit ich es so anforderungsgerecht hingebogen habe.

Grüße
Biber

Hallo,

danke für deine Mühe.

Das ganze funktioniert soweit. Ich habe nur noch das Problem, dass ich 6 mal den Ausruf "Prozess onte nicht zugreifen.....da bereits verwendet wird" - es werden aber alle VErzeichnisse verschoben.

Ein Problem welches ich noch habe ist, dass keine Dateien verschoben werden - sondern nur die Ordner.

PS: Damit er keinen Ordner anzeigt der ein komplettes Jahr enthält - also "Jahr 2006", "Jahr 2005" etc... kann ich da einfach mehrere && machen, oder wie kann man dies geschickter lösen?

MfG Sandro

Moin Saggi,

das können wir natürlich jetzt schrittweise verfeinern.
Bisher ist es ja nur eine Konzeptskizze, ein Proof of Concept.

Ich habe nur noch das Problem, dass ich 6 mal den Ausruf "Prozess onte nicht zugreifen.....da bereits verwendet wird" - es werden aber alle VErzeichnisse verschoben.

Das wird daran liegen, dass ja nun die Verzeichnisstruktur, die mit FOR/D durchwackelt wird, gleichzeitig geändert wird.
Dann machen wir das stufenweise - wir ermitteln erst die Unterverzeichnisse, die geMOVEd werden sollen und machen das eigentliche MOVE danach.

Ein Problem welches ich noch habe ist, dass keine Dateien verschoben werden - sondern nur die Ordner

Okay, das kann daran liegen, dass ich auch bisher nur die Verzeichnisse anfasse und keine Zeile für die Einzeldateien im (Ober-)Ordner vorgesehen habe.

Ausgehen vom Batch oben dann:

::----das wird ein Zwischen-Batch.cmd
@echo off
REM Zweistufiges Vorgehen - erst alles rausschreiben, was später verschoben werden soll:
Set "Tmpbat=%temp%\tmp.bat"  
if exist "%tmpbat%" del "%tmpbat%"  
for /D %%i in ("x:\HauptOrdner\*") do @(  
     If exist "%%i\*.*" ECHO move "%%i\*.*" "%%i\Jahr 2006\" >>"%tmpbat%"  
     for /D %%j in ( "%%i\*") do @(  
        echo "%%~nxj"|find /v "Jahr 2006" >nul && ECHO move "%%j" "%%i\Jahr 2006" >>"%tmpbat%"  
     ) ) 
if exist "%tmpbat%" call "%tmpbat%"  
if exist "%tmpbat%" del "%tmpbat%"  

So in etwa wäre die ungetestete Skizze, wenn davon ausgegangen werden könnte, dass sich in jeder Unterstruktur ein Ordner "Jahr 2006" befindet.
Wenn wir das noch erweitern dahingehend, das sich dort eintweder ein Ordner "Jahr 2005" ODER ein Ordner "Jahr 2006" oder ein Ordner "Jahr 2007" oder eben nichts von alledem befindet:

::----das wird ein erweiterter Zwischen-Batch.cmd
@echo off & setlocal
REM Zweistufiges Vorgehen - erst alles rausschreiben, was später verschoben werden soll:
Set "Tmpbat=%temp%\tmp.bat"  
if exist "%tmpbat%" del "%tmpbat%"  
for /D %%i in ("x:\HauptOrdner\*") do @(  
     For /L %%a in (2005,1,2008) do if exist "%%i\Jahr %%a" call :DoTheMoveTo "%%i" "Jahr %%a"  
)
if exist "%tmpbat%" call "%tmpbat%"  
if exist "%tmpbat%" del "%tmpbat%"  
goto :eof

~~~~~~
:DoTheMoveTo Parameter 1 ist das Oberverzeichnis über "Jahr 200x"; Param2 das gefundene Verzeichnis "Jahr 200x"  
     If exist "%~1\*.*" ECHO move "%~1\*.*" "%~1\%~2\" >>"%tmpbat%"  
     for /D %%j in ( "%~1\*") do @(  
        echo "%%~nxj"|find /v "%~2" >nul && ECHO move "%%j" "%~1\%~2" >>"%tmpbat%"  
     ) 
goto :eof