Sicherung Fileserver

CLS
@ECHO OFF 

set CURRENTTIME=%TIME::=.%
set CURRENTTIME=%CURRENTTIME:~0,8%
set ARCHIVNAME=%date:~-4%%date:~3,2%%date:~0,2%__%time:~0,2%%time:~3,2%

mkdir \\IP\Sicherung\%ARCHIVNAME%\
timeout /t 5
@ECHO OFF 

COLOR 1F


CHCP 1252


SET quelle=D:\Laufwerke\
SET ziel=\\IP\Sicherung\%ARCHIVNAME%\
REM ------------------------------------
CHCP 850
CLS

ECHO. 
ECHO ++++++++++++++++++++++
ECHO +++ DATENSICHERUNG +++
ECHO ++++++++++++++++++++++
ECHO.

SET timestamp=%date:~-4%%date:~3,2%%date:~0,2%__%time:~0,2%%time:~3,2%

ECHO.
ECHO VERZEICHNISSE CHECKEN...
IF NOT EXIST %quelle% GOTO ERRSOURCE
IF NOT EXIST %ziel% GOTO ERRDEST

ECHO.
ECHO SYNCHRONISIERUNG STARTEN...
ECHO.
ROBOCOPY %quelle% %ziel% /COPY:DAT /MIR /R:2 /W:20
IF %ERRORLEVEL% GEQ 8 GOTO ERRCOPY 
GOTO END

REM FEHLERBEHANDLUNG
:ERRCOPY
ECHO.
ECHO FEHLER: Mindestens eine Datei konnte nicht kopiert/gel”scht werden!
ECHO %timestamp%  FEHLER: Mindestens eine Datei konnte nicht kopiert/geloescht werden! >> "%~n0.log"  
GOTO ERREND
:ERRSOURCE
ECHO.
ECHO FEHLER: Quellverzeichnis nicht vorhanden!
ECHO %timestamp%  FEHLER: Quellverzeichnis nicht vorhanden! (%quelle%) >> "%~n0.log"  
GOTO ERREND
:ERRDEST
ECHO.
ECHO FEHLER: Zielverzeichnis nicht vorhanden!
ECHO %timestamp%  FEHLER: Zielverzeichnis nicht vorhanden! (%ziel%) >> "%~n0.log"  
GOTO ERREND

REM SHIT HAPPENS
:ERREND
COLOR 4F
ECHO.
ECHO VORGANG MIT FEHLERN ABGESCHLOSSEN
ECHO.
ECHO Dieses Fenster schliesst sich in 5 Sekunden.
ECHO.
ping -n 5 localhost >nul
EXIT

REM HAPPY END
:END
COLOR 2F
ECHO.
ECHO VORGANG ERFOLGREICH ABGESCHLOSSEN
ECHO.
ECHO Dieses Fenster schliesst sich in 5 Sekunden.
ECHO.
ping -n 5 localhost >nul
EXIT