Windows Server 2012 R2 Gruppenrichtline Verteilung Batch-Script bei Anmeldung (Excel Addin)

@echo off
:: Kopieren des Excel-Addins "set_calculation_to_automatic_at_start.xlam" 
:: und Implementierung über die Windows-Registry in Excel
:: Der Freigabename "share" des Scripts muss verändert werden, 
:: wenn "share" nicht als Freigabe auf dem Server besteht. 
:: Variable dazu: sourcepath (Zeile 30)
:: Es werden der Zeit nur Computer mit MSOffice 2013 unterstützt!!
:: letztes Update: 31.08.2018
:: Autor:

::vars
SET d=%date%
SET sorteddate=%d:~-4%-%d:~3,2%-%d:~0,2%

::Erstellen des Log Ordners, wenn nicht vorhanden
if not exist %~dp0\logs_excel_addin mkdir %~dp0\logs_excel_addin

::Prüfen der ZULETZT installierten Office Version
reg query HKEY_CLASSES_ROOT\Excel.Application\CurVer
if %ERRORLEVEL% == 1 goto nooffice

for /f "tokens=3 delims=." %%a in ('reg query "HKEY_CLASSES_ROOT\Excel.Application\CurVer"') do set officever=%%a  
if %officever%==11 GOTO office2003
if %officever%==12 GOTO office2007
if %officever%==14 GOTO office2010
if %officever%==15 GOTO office2013

:office2013
::Einstellungen (Falls benötigt)
SET sourcepath=%Logonserver%\share\
SET installpath=%appdata%\Microsoft\AddIns
SET filename=set_calculation_to_automatic_at_start.xlam

::Kopieren wenn Addin-Datei nicht vorhanden
if exist %installpath%\%filename% GOTO checkreg
xcopy %sourcepath%\%filename% %installpath%\*.* 

::Prüfen ob Registry-Eintrag vorhanden ist
:checkreg
for /f "tokens=2* delims=	 " %%A in ('reg query "HKCU\Software\Microsoft\Office\15.0\Excel\Options" /v OPENauto 2^>NUL ^| find "%installpath%\%filename%"') do set Blub=%%B  
if not defined blub (
	goto setreg
)
echo Registry-Eintrag fuer Addin vorhanden.

exit

::Erstellen des Registry-Eintrags
:setreg
set regkeypath=HKCU\Software\Microsoft\Office\15.0\Excel\Options
reg add %regkeypath% /V "OPENauto" /t REG_SZ /d "%installpath%\%filename%"  
echo Registry-Eintrag fuer Addin erstellt.

::Log feedback
echo %sorteddate% = Das Addin wurde oder ist erfolgreich auf %computername% installiert > %~dp0\logs\xcreated_%sorteddate%_%computername%_o2013.log

::Ende nach Kopiervorgang und setzen des Registry-Eintrag
exit



:nooffice
echo %sorteddate% = Kein Office installiert auf %computername%. Kopiervorgang des Addins abgerochen. > %~dp0\logs_excel_addin\failed_%sorteddate%_%computername%_keinOffice.log
GOTO exit
:office2003
echo %sorteddate% = Office 2003(%officever%.0) auf %computername%. Kopiervorgang des Addins abgerochen. > %~dp0\logs_excel_addin\failed_%sorteddate%_%computername%_o2003.log
GOTO exit
:office2007
echo %sorteddate% = Office 2007(%officever%.0) auf %computername%. Kopiervorgang des Addins abgerochen. > %~dp0\logs_excel_addin\failed_%sorteddate%_%computername%_o2007.log
GOTO exit
:office2010
echo %sorteddate% = Office 2010(%officever%.0) auf %computername%. Kopiervorgang des Addins abgerochen. > %~dp0\logs_excel_addin\failed_%sorteddate%_%computername%_o2010.log
GOTO exit



:exit
exit