Printjobs mit PDF komprimieren für VPN-Übertragung

@echo off
REM Diese Datei ist nur dafür gut, dass FreePDF direkt wieder schliesst.

start c:\spooler\rename.bat %1 %2 %3 %4 %5 %6 %7 %8 %9
exit

@echo off

REM Folgender Block entfernt in der Variable %1 die Anführungszeichen und die Endung .pdf

set pdfname2=%1
set pdfname=%pdfname2:"=%  
for /f "tokens=1,2,3,4 delims=\" %%i in ("%pdfname%") do set pdfname2=%%l  
set pdfname=%pdfname2:.pdf=%
for /f "tokens=1 delims=" %%i in (%4) do @set printername=%%i  
for /f "tokens=1,2,3 delims=:," %%i in ("%time%") do @set printtime=%%i%%j%%k  
set pdffilename=#%printername%#%6#%username%#%printtime%#ID%random%#%pdfname%
pushd c:\spooler\temp

REM Hier wird die Datei im TEMP Ordner erst mal umbennant, damit sie einen Druck von einem
REM anderen Nutzer, der eine Datei mit dem selben Namen ausdrucken will, nicht blockiert.

ren %1 "%pdffilename%"  
mode con cols=32 lines=4
title PDFPrint

REM Abfrage der Kopien. Dann wird nochmal umbenannt, damit die Anzahl auch im Dateinamen steht.

echo.
echo  Wie viele Kopien moechten Sie?
echo.
set /p copy=
if "%copy%"=="" @set copy=1  
set newpdffilename=#%printername%#%6#%copy%#%username%#%printtime%#ID%random%#%pdfname%
ren "%pdffilename%" "%newpdffilename%"  
popd
start /min c:\spooler\pdfspooler.bat "%newpdffilename%" %2 %3  

REM Die 3. Bat wird aufgerufen, damit der Kopiervorgang im Hintergrund abläuft.

exit

@echo off
title WIRD GEDRUCKT...
mode con cols=27 lines=4
echo.
echo  FENSTER NICHT SCHLIESSEN!

REM Hier werden wieder die Anführungszeichen entfernt.

set pdffilename2=%1
set pdffilename=%pdffilename2:"=%  
pushd c:\spooler\temp
copy /Z %1 "\\%2\%3\%pdffilename%.pdf"  

REM Für Fehlerprotokollierung REM in FOLGENDER Zeile entfernen.
REM if %errorlevel% equ 1 (echo %date% %time% %username% %pdffilename% >> c:\spooler\log\error.log)

del %1 /f /s /q
popd

REM Fuer Protokollierung aller Druckvorgaenge REM in FOLGENDER Zeile entfernen.
REM echo %date% %time% %pdffilename% >> c:\spooler\log\spool.log

REM Die Variablen %2 und %3 sind IP-Adresse und freigegebener Ordner auf dem Client.
REM Sie stammen von der Befehlszeile in FreePDF und werden von rename.bat und print.bat mit übergeben.

exit

@echo off
del c:\spooler\temp\*.* /f /s /q

[directories]
c:\pdfprint\pdfspooler="c:\pdfprint\pdfprint.bat"  

@echo off
del c:\pdfprint\pdfspooler\*.* /f /s /q
del c:\pdfprint\dirmonitor.log /f /s /q
net start sdirmon

@echo off
REM Folgende Schleife liest aus dem Dateinamen die entsprechenden Parameter für den Druck.
for /f "tokens=1,2,3,4 delims=#" %%i in (%1) do @set printername="%%j"&set duplex=%%k&set copy=%%l  

REM Diese Schleife entfernt C:\PDFPrint\PDFSPOOLER aus dem Dateinamen damit die Datei mit ren umbenannt
REM werden kann.
for /F "tokens=1,2,3,4 delims=\" %%i in (%1) do @set pdffilename="%%l"  
pushd c:\pdfprint\pdfspooler

REM Der Abschnitt check wartet ab, bis die Datei vollständig auf dem Client angekommen ist.
:check
ping 127.0.0.1 -n 1
ren %pdffilename% %pdffilename%
if not exist %1 goto:eof
if %errorlevel% equ 0 (goto print) else (goto check)


:print

REM Hier wird bewusst auf die Option -c von pdfp.exe verzichtet, da sie nicht richtig funktioniert.

for /l %%i in (1,1,%copy%) do (c:\pdfprint\pdfp.exe -p %printername% -d %duplex% %1)
del %1 /f /s /q
popd

@echo off
taskkill /f /im acrord32.exe /fi "USERNAME eq System"  
taskkill /f /im pdfp.exe /fi "USERNAME eq System"  
taskkill /f /im cmd.exe /fi "USERNAME eq System"  
del c:\pdfprint\pdfspooler\*.* /f /s /q