gogoflash
Goto Top

Druckkontingentierung auf Windows Servern mit Boardwerkzeugen/Freewaretools

Anhand eines Projektes zur Kontingentierung von Druckseiten auf Windows Servern wird gezeigt, wie man das Eventlog filtert und daraus mit einfachsten Mitteln Informationen daraus ziehen kann. Falls der Nutzer das Kontingent überschritten hat, wird im das Recht zum Drucken verweigert.Genutzt werden hierzu die Batchbefehle unter DOS.

Kontigentierung


back-to-top--------- Ablauf ----------------
Ablauf bevor ein paar Codeschnippsel gezeigt werden.
1) Auslesen der User (Personen) aus dem Active Directory. Die Namen werden in eine Userlist.txt ausgegeben. Hiermit kann später das Drucklog nach Usern gefiltert werden.

2) Herausfiltern bestimmter Nutzer. Entweder weil sie bereits gesperrt wurden, oder weil sie nicht unter dem Kontingent leiden sollen.

3) Mit DUMPEL wird das Eventlog seit Monatsbeginn ausgelesen, explizit werden dabei die Druckereignisse herausgefiltert.Um die Tage seit Monatsbeginn auszulesen, wird das getalldatetimevar.cmd von BIBER genutzt.

4) Herausfiltern der einzelnen Drucker anhand der Portbezeichnung

5) Die Ausgabe von DUMPEL wird formatiert. Für jeden User wird eine Datei angelegt in der die bisher gedruckten Seiten drinstehen. (Das Filtern erfolgt mit SED)

6) Addition der einzelnen Seiten und Prüfung auf Kontingentüberschreitung.

7) Maßnahmen bei Kontingentüberschreitung E-Mail Benachrichtigung, Desktopbenachrichtigung, Sperrung des Druckers durch Rechte setzen.

8) Erstellung von Nutzerinformationen und einer Statistik, um sie zum Beispiel von KIX bei der Anmeldung auszulesen.

9) Eintüten in Subroutinen und Schleifen.

10) Batch mit allem zusammen.

11) Abfallprodukte:
Als kleines vorläufiges Abfallprodukt entsteht ein kleines Script, dass den Admin oder User über bestimmte Events per Mail informiert.Hieraus entstanden..
Vielleicht kann man ja daraus mehr machen.

Dieses Skript sollte natürlich mehrmals am Tag durchlaufen um eine zeitnahe Protokollierung zu erhalten. Es gibt einige Freewareprogramme, die dieses Skript jede Minute ausführen können.

Ablauf Ende ----------------

Fangen wir an.

back-to-topAuslesen der Benutzer in einer OU im AD
Erstmal müssen wir eine Nutzerliste erstellen, diese brauchen wir, um die Ausgabe nach den Nutzern zu filtern. Es empfiehlt sich, die bei jedem Durchlauf durchzuführen, es können ja schnell neue Nutzer angelegt werden.

Ausgelesen wird aus der Domäne.de und den OUs OU=hinten, ou=berlin; nur Objekte die Person sind.
Genutzt wird dazu ldifde, was auf jedem Windows Server zufinden ist. (NT weiß ich nicht)

ldifde -f ExportUsers.ldf -s DC -d "ou=hinten,ou=Berlin,dc=domäne,dc=de" -p subtree -r "(objectClass=person)" -l "SamAccountName"  

Gibt uns folgendes aus:
dn: CN=Schwanz,OU=hinten,OU=Berlin,DC=domäne,DC=de
changetype: add
sAMAccountName: userA

dn: CN=Ab,OU=hinten,OU=Berlin,DC=domäne,DC=de
changetype: add
sAMAccountName: userB

Interessieren tun uns nur die samaccountName: Einträge. Diese Filtern wir folgender Maßen aus.
for /f "tokens=2 delims= " %%a in ('find "sAMAccountName:" ExportUsers.ldf ') do (echo %%a>> userlistall.txt)  

Jetzt haben wir eine Liste (userlistall.txt) die so aussieht.
UserA
UserB

back-to-topAnhand einer gesperrt.txt Datei (diese wird vom Skript erzeugt wollen wir bestimmte Nutzer rausfiltern). Diese werden beim Durchlauf nicht mehr berücksichtigt.

So sehen die beiden Dateien aus:
Userlist.txt :
UserA
UserB
UserC

Gesperrt.txt
UserC

gibt uns mit diesem Code

IF EXIST gesperrt.txt for /f %%x in (%userinfo%\%druckport%\gesperrt.txt) DO call :userf %%x
Goto:eof
:userf
	for /f "skip=2 tokens=1 delims= " %%a in ('find /V "%1" userlistall.txt') do (echo %%a >> userlist.txt)  
goto :eof

Eine userlist.txt mit den erlaubten Nutzern:
UserA
UserB

Dieser Nutzer waren bisher nicht gesperrt und werden jetzt ausgewertet.

back-to-topMithilfe von Dumpel das Printlog auslesen.

dumpel -f d:\drucker.log -m print -t -s \\Druckserver -l System -e 10 -format s -d 10
-d 10 steht für die letzten 10 Tage.
-e 10 steht für die EventID
-l System für Systemlog (Application wenn man in diesem Log was suchen möchte)
-m print Eventname

Mit dem getalldatetimesvar.cmd vom Biber kann man die Tage per %dd% übergeben.

Die Ausgabe sieht dann so aus:
44	VE.PDF	UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	481437	1	
46	VE.PDF	UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	93056	1	
48	VEpdf	UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	142196	1	
50	VE_Ban.pdf UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	139116	1
4 Microsoft PowerPoint - 20060201_.ppt	UserB	Canon iR C3200 PCL5c	IP_172.22.44.71 50997	1
58	VE_Ban1.pdf UserA	Canon iR C3200 PCL5c	IP_172.22.44.88	139116	1

In der dritten Spalte wird der Nutzer angegeben. In der letzten Spalte die gedruckten Seiten.
In der drittletzten Spalte steht der Name des Druckports, davor der Druckername.

back-to-topAuswertung der Ausgabe von DUMPEL.

Eine Auswertung mit
for /f "tokens=3,8 delims= " %%a in (drucker.log) do (echo %%a;%%b>> Logdatei.txt)   
bei den Einträgen von Microsoft aufgrund einer zusätzlichen Spalte (Microsoft [Leerzeichen]Powerpoint) nur Müll aus.

Erstmal filtern wir nach dem Druckerport, das sollte der Drucker sein der Kontingentiert werden soll.
Wir filtern nach dem 172.22.44.71 Port, das ist ziemlich billig, durch FIND zu machen.

find "IP_172.22.44.71" druck.log > druckport  

Die Ausgabe in der druckport Datei sieht dann so aus (die FIND Einträge hab ich jetzt mal nicht mitgenommen)

44	VE.PDF	UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	481437	1	
46	VE.PDF	UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	93056	1	
48	VEpdf	UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	142196	1	
50	VE_Ban.pdf UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	139116	1
4 Microsoft PowerPoint - 20060201_.ppt	UserB	Canon iR C3200 PCL5c	IP_172.22.44.71 50997	1

back-to-topAusfiltern vom User.
Erstmal filtern wir nach einem User.
find "userA" drucker.log > userA  

Ausgabe in userA
44	VE.PDF	UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	481437	1	
46	VE.PDF	UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	93056	1	
48	VEpdf	UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	142196	1	
50	VE_Ban.pdf UserA	Canon iR C3200 PCL5c	IP_172.22.44.71	139116	1

Was wir jetzt machen müssen, ist die letzte Spalte rauszufiltern. Dies machen wir in mehreren Schritten.

Mithilfe von SED (gleich kommt die Aufklärung)
SED -e "s/^.*IP_172.22.44.71 /SET /p" -e "d" <userA > userA2  
Mit diesem Befehl wird alles was vor IP_172.22.44.71 in UserA ausgeschnitten inkl IP_172.22.44.71

sieht die Ausgabe in der UserA Datei aus:
SET 481437	1	
SET 93056	1	
SET 142196	1	
SET 139116	1

Jetzt schneide ich die ersten beiden Spalten aus:
for /f "tokens=1,2,3 delims= " %%a in (userA2) DO (echo %%c >>userA3)  

UserA3 Datei sieht so aus:
1
1
1
1

Was wir jetzt haben ist eine Liste für jeden User in der die Anzahl der Druckseiten drinsteht. Jetzt muss nur noch die Zahl addiert werden und mit einem Kontingent verglichen werden.


Diese mehreren Schritte lassen sich auf einen Einzeiler reduzieren, der ohne Zwischendateien arbeitet.

for /f "tokens=1,2,3 delims= " %%a in ('find "userA" drucker.log^|SED -e "s/^.*IP_172.22.44.71 /SET /p" -e "d"') DO (echo %%c >> userA)  
back-to-topAddieren der Inhalte von UserA und mit einem Kontingent vergleichen.
Falls es überschritten wird, können dann Maßnahmen getroffen werden. Gleichzeitig wird für jeden Nutzer eine Datei erstellt in der die Gesamtzahl der Seiten drinsteht. Dies kann man z.B. per KIX dann auslesen, um den Nutzer über sein Kontingent zu informieren.
Zum Addieren wird der SET Befehl unter DOS benutzt. (Boardwerkzeug)

REM Kontingent festlegen
set kontigent=100
for /f %%a in (userA) DO call :inner %%a
	:inner
		REM Hochzählen bedeutet zahl=zahl+%1
		Set /a "Zahl+=%1"  
		REM Infos fuer Späteres KIx auslesen erzeugen
		echo %user% %zahl% > %userinfo%\%druckport%\%user%

REM Abbruchbedingung eingefügt, damit Schleife nicht unnötig lang 
REM durchgelaufen wird
		
IF %abbruch%==-1 goto :endin

		REM Falls Kontigent überschritten wird die Subroutine Abfertigen aufgerufen		
		IF %kontingent% LEQ %Zahl% call :abfertigen
		
		:endin

goto :eof

back-to-topMaßnahmen

Nutzer in eine gesperrt.txt einfügen:

echo %user% >> %userinfo%\%druckport%\gesperrt.txt

net send %user% Kontigent erschöpft

Sperrung des Druckers Methode A

subinacl /printer %printer% /deny=domäne\%user%=F

Sperrung des Druckers Methode B

Gruppe erstellen. Dieser Gruppe die Rechte am Drucker verweigern und den gewünschten User in diese Gruppe einfügen.Dies Funktioniert meines Wissens und laut meiner Server auch nur auf Domänencontroller.
Net group gruppenname %user% /add 
E-Mail Benachrichtigung mit blat:
SMTP Server 172.22.44.xxx und Blindcopy an Admin.

blat -installSMTP 172.22.44.xxx drucker@domaene.de
blat zuviel.txt -to %user%@domaene.de -bc admin@domaene.de -s "Kontingentüberschreitung auf Drucker XYZ"  

In der zuviel.txt Datei liegt der Textbody der zu versenden ist.


In Arbeit.

back-to-topGroße Schleife und Subroutinen
Mit Hilfe der userlist.txt kann ich den gesamten Kram in eine große Schleife pumpen.
for /f %%x in (userlist.txt) do (set user=%%x && call :sua)
:eof
:sua
.... Mach was.....
:eof

Und den ganzen Kram in Subroutinen stellen.
Wie man das macht sieht man in diesem guten Tutorial:

HowTo - Wie man Subroutinen in Batchfiles erstellt

back-to-topAlles zusammen (Beta Version mit vielen Zwischendateien und Tempdateien):

REM Druckkontigent V 0.02 Datum:10.02.06

REm Verzeichnisse vorbereiten
	
	set stamm=d:\scripte\drucker
	set temp1=%stamm%\temp1
	set temp2=%stamm%\temp2
	set logpfad=%stamm%\log
	set userinfo=%stamm%\user
	md %temp1%
	md %temp2%
	md %logpfad%
	md %userinfo%
	del %logpfad%\userlist.txt

REM Kontigent setzen
	set kontingent=100

REM Variablen setzen fuer AD
	REM Domänencontroller
	set domainc=Server-DC
	REM Domänenname
	set dc1=domaene
	set dc2=de
	REM OU Informationen
	set ou1=Berlin
	set ou2=User

REm Variablen fuer Drucker setzen
	REM Druckerport
	set druckport=hplj4100
	REM Drucker UNC
	set printer=\\Printserver\pr-hplj4100
	REM Printserver (wo liegt die Logdatei)
	set server=\\Printserver
REM -------------------------------------

getalldatetimevar.cmd /s

REM Aufspaltung in Main und Subroutinen 
call :main
goto :end


REM -------------------------------------
REM Subroutinen
:main
	md %userinfo%\%druckport%

	REM Jetzt gehts Los

	REM Auslesen der Tage seit MOnatsbeginn wird benötigt für DUmpel
	REM Noch zu machen
	
	REM Auslesen der Benutzer für Filter
	ldifde -f %logpfad%\ExportUsers.ldf -s "%domainc%" -d "ou=%ou2%,ou=%ou1%,dc=%dc1%,dc=%dc2%" -p subtree -r "(objectClass=person)" -l "SamAccountName" >> %logpfad%\log.txt  
	REM Die Ausgabe muß nach Accountnamen gefilter werden
	find "sAMAccountName:" %logpfad%\ExportUsers.ldf > %logpfad%\userlist.tmp  
	REM AUschneiden der ersten 2 Zeilen die durch find reinkommen
	for /f "skip=2 tokens=2 delims= " %%a in (%logpfad%\userlist.tmp) do (echo %%a>> %logpfad%\userlist.txt)  
	del %logpfad%\userlist.tmp
	del ldif.log
	del %logpfad%\ExportUsers.ldf
	REM Userlistall.txt enthält alle Nutzer aus der OU
	copy %logpfad%\userlist.txt %logpfad%\userlistall.txt
	
	REM Rausfiltern der bereits gesperrten User (siehe Subroutinen TEil)
	REM Wird benötigt um Benutzer nicht mehrmals zu benachrichtigen
	IF EXIST %userinfo%\%druckport%\gesperrt.txt for /f %%x in (%userinfo%\%druckport%\gesperrt.txt) DO call :userf %%x

	REM Druckprotokoll auswerten 
	REM Zur Zeit -d 10 für 10 Tage
	dumpel -f %logpfad%\druck.log -m print -c -s \\debe-as-01 -l system -e 10 -d %dd% -format s
	REM Drucker rausfiltern
	find "%druckport%" %logpfad%\druck.log > %logpfad%\%druckport%  
	del %logpfad%\druck.log 


	REM Berechnung durchführen (siehe Subroutinen Teil)	

	for /f %%x in (%logpfad%\userlist.txt) do (set user=%%x && call :rech)


	REM Statistik
	REM Ausgabe einer Liste über Druckaufkommen
	for /f %%x in (%logpfad%\userlistall.txt) do (set user=%%x && call :statistik)
goto :eof

REM -------------------------------------
:rech
	REM Ausgabe so filtern, dass nur noch Dokumentenzahl drinsteht
		find "%user%" %logpfad%\%druckport% > %temp1%\%user%  
		SED -e "s/^.*"%druckport%" /SET /p" -e "d" <%temp1%\%user% >%temp2%\%user%  
		del %temp1%\%user%
		REM In der Logdatei die Zeitenzahlen rausfiltern und in %temp1% ausgeben
		for /f "tokens=1,2,3 delims= " %%a in (%temp2%\%user%) DO (echo %%c >>%temp1%\%user%)   
		del %temp2%\%user%

	REM Addieren der Seitenzahlen
	set /A "zahl=0"  
	set /A "abbruch=0"		  
	for /f %%a in (%temp1%\%user%) DO call :inner %%a
	:inner
		Set /a "Zahl+=%1"  

		REM Infos fuer Späteres KIx auslesen erzeugen
		echo %user% %zahl% > %userinfo%\%druckport%\%user%

		REM Abbruchbedingung Eingefügt, damit Schleife nicht unnötig lang durchgelaufen wird
		IF %abbruch%==-1 goto :endin

		REM Falls Kontigent überschritten wird die Subroutine Abfertigen aufgerufen		
		IF %kontingent% LEQ %Zahl% call :abfertigen
		
		:endin

goto :eof

REM ENDE von RECH
REM -------------------------------------
REM gesperrte Nutzer rausfiltern	
:userf
	find /V "%1" %logpfad%\userlist.txt > %logpfad%\userlist.tmp  
	del %logpfad%\userlist.txt
	for /f "skip=2 tokens=1 delims= " %%a in (%logpfad%\userlist.tmp) do (echo %%a >> %logpfad%\userlist.txt)  
	del %logpfad%\userlist.tmp
goto :eof

REM -------------------------------------
REM Was soll mit den passieren die das Kontigent überschritten haben
:abfertigen
	set /a "abbruch=-1"  
	echo %user% >> %userinfo%\%druckport%\gesperrt.txt
	REM net send %user% Kontigent erschöpft
	REM Sperrung zur Sicherheit auskommentiert
	REM subinacl /printer %printer% /deny=%dc%\%user%=F
:goto :eof

REM -------------------------------------
REM Ausgabe der Statistik
:statistik
for /f "tokens=1,2 delims= " %%a in (%userinfo%\%druckport%\%user%) DO (IF NOT %%b==0 echo %%a %%b >> "%userinfo%\%druckport%.txt")  
:goto :eof
REM -------------------------------------
:end

10) Eintüten ins System.
Die Hauptdatei kann als Geplanter Task ausgeführt werden.
Am ersten eines Monats, sollte man falls man Methode B zur Sperrung genutzt hat. Die gesperrten Nutzer aus der Gruppe entfernen.

net group Gruppenname %user% /delete

back-to-topAbfallprodukte:

back-to-topBenachrichtigung über bestimmte Events per Mail


Hier wird das Eventlog des letzten Tages (-d 1) vom Server (\\Servername), mit der EventID 10 und Eventname Print aus dem Systemlog an den admin geschickt.
Läßt sich bestimmt leicht anpassen.
Per "Wiederkehrenden Task" kann dies einmal am Tag ablaufen. Willst Du über die Events schnell informiert werden und sie auch nicht doppelt und dreifach bekommen, muss es natürlich angepasst werden. Frag einfach mal nach.

dumpel -f eventlog.log -m print -c -s \\Servername -l system -e 10 -d 1 
blat -installSMTP 172.22.44.4 servername@domane.de
IF EXIST eventlog.log blat eventlog.log -to admin@domaene.de -s "Infos über Event"  

Weitere Anpassungen und Anregungen werden gerne in das Script aufgenommen.
Freue mich auf eine Diskussion.
Hier zur Diskussion:


Ich danke hiermit auch dem freundlichen BIBER für seine Optimierungen des Codes und seine Vorschläge.

Gruß Miguel


back-to-topSoftwarequellen:
Dumpel (Printlog ausgeben)
http://www.microsoft.com/windows2000/techinfo/reskit/tools/existing/dum ...

BLAT
http://www.blat.net/

SED
http://www.windowsitpro.com/Articles/Index.cfm?ArticleID=5697

VAR SET
http://home.mnet-online.de/horst.muc/german.htm

Subinacl
http://www.microsoft.com/downloads/details.aspx?FamilyID=e8ba3e56-d8fe- ...

Content-Key: 25758

Url: https://administrator.de/contentid/25758

Printed on: March 3, 2024 at 02:03 o'clock

Member: Biber
Biber Feb 11, 2006 at 18:38:18 (UTC)
Goto Top
Prima, gogoflash,

gutes Konzept und ein Super-Beispiel dafür, was sich mit viel Ideen und ohne viel Programmierung (ohne auf C# oder .NET zurückzugreifen) erreichen lässt.

Mal sehen - vielleicht kann ich Dir mithelfen, es noch ein wenig modularer/flexibler zu gestalten - dann ließen sich damit auch andere Logfiles (vor allem das EventLog!!) durchflöhen.

Danke!

Frank / der Biber aus Bremen
Member: heffa
heffa Mar 09, 2006 at 08:44:47 (UTC)
Goto Top
Hallo,

hast du nett gemacht und gut erklärt... Danke!

ich möchte noch auf diese schlüsselfertige und schöne Lösung hinweisen: http://www.syneticon.net/service/w2k/drucker-accounting.html

Bietet unter anderem eine grafische Auswertung in Excel... manche Chefs schätzen so etwas sehr face-wink

Schöne Grüsse Heffa
Member: gogoflash
gogoflash Jun 08, 2006 at 14:39:59 (UTC)
Goto Top
Hallo,

ich hab mir mal die schlüsselfertige Lösung angesehen. Sie ist recht gut und gibt eine umfangreiche Aufstellung der Druckmengen.

Im gegensatz zu meiner Lösung ist hier nur eine Auswertung möglich und keine Sperrung bei Überschreiten von den Kontigenten. (Läßt sich sicherlich auch noch ins Makro einbauen)


Gruß Miguel
Member: laberdasch
laberdasch Jun 08, 2006 at 16:14:35 (UTC)
Goto Top
Respekt!!
Mitglied: 42687
42687 Jun 30, 2009 at 11:55:14 (UTC)
Goto Top
Wirklich toll, bin wirklich interessiert. Wäre aber ganz nett, wenn du alles mal in einen Ordner packen könntest und den Zippen und mir vielleicht per mail zukommen lassen. Denn bsp die getalldatetimevar.... und die SED kann ich nicht finden. Vielen Dank. Ich schick dir meine Mailadresse per PN.

Vielen Dank...


Peter
Member: mkrasselt1
mkrasselt1 Apr 26, 2012 at 04:38:16 (UTC)
Goto Top
Hallo gogoflash face-smile
Ist zwar schon wieder etwas alt, aber deine Umsetzung ist genial ;)
Nur wir haben eine Änderung vor:
Wo mus sich etwas ändern, damit für Jeden Nutzer ein Anderes Kontigent gezählt wird ?
Wir wollen ein System zum Aufladen einführen, und das müsste ja dann bei jedem Nutzer
einzeln gebucht werden. Ich denke die Variable Kontigent ist die Stelle die ich ändern muss.
Am Besten sicher über das auslesen aus einer Datei des Nutzers, auf die er Keinen Schreibzugriff hat.
(Managebar über Webfrontend zum Beispiel)
Ist das der Richtige weg ?
Für die Finale Version müsste ich nru alles in eine Batchdatei Packen oder ?

Vielen Dank, mkrasselt1
Member: gogoflash
gogoflash May 25, 2012 at 00:21:29 (UTC)
Goto Top
Zitat von @mkrasselt1:
Hallo gogoflash face-smile
Ist zwar schon wieder etwas alt, aber deine Umsetzung ist genial ;)

Danke.

Nur wir haben eine Änderung vor:
Wo mus sich etwas ändern, damit für Jeden Nutzer ein Anderes Kontigent gezählt wird ?
Wir wollen ein System zum Aufladen einführen, und das müsste ja dann bei jedem Nutzer
einzeln gebucht werden. Ich denke die Variable Kontigent ist die Stelle die ich ändern muss.

Ich denke auch. Da du aber dynamisch die Kontingente ändern möchtest, müsste ich mal genauer hören ,wie du dir das Prozedere denkst.

Ist es auch eine Windows Domäne oder ähnliches? Würde mich auf Feedback freuen, dann könnte man das Skript noch besser machen.

Gruss mq
Member: mkrasselt1
mkrasselt1 May 25, 2012 at 04:33:29 (UTC)
Goto Top
Okay, so ist das System gedacht.
Im Jahreszyklus werden die bereits Gedruckten Seiten mit den Restkontigent verrechnet.
So das im letzten Jahr überschüssiges Kontigent erhalten bleibt, aber alle Drucker-Zähler zurückgesetzt werden.
Ansonsten können die Nutzer das ganze Jahr über verschieden Mengen an Kontigent erwerben(z.B. 50,100,500,1000 Seiten). Sobald sie es erwerben, können sie es auf ihr Konto aufbuchen(wollte ich dann über ein Webfrontend realiesieren). Dabei wird auch über ein leicht abgewandeltes Script ihre Druckberechtig wieder gesetzt, falls sie fehlen sollte. Und damit kann ein Nutzer, der in einer Woche mal die letzten 10 Seiten seines Kontigents aufgedruckt hat, sich eine neue Karte kaufen, die Nummer registrieren und sofort wieder Berechtigung haben. Für die Menge die dann aufgebucht wurde.


Ich hoffe ich habe verständlich gemacht, was ich möchte. Falls etwas zu aufwändig sein sollte, kannst du es gerne lassen, und ich bau es in mein Frontend mit ein(und rufe es Remote von nem Linuxserver als Cronjob auf).

[ich kenne mich nur in DOS nicht gut aus....]

Danke sagt Michael