EXCEL VBA Zellen verbinden. MERGE

Sub AutoMerge()
    On Error Goto Errhandler
    Dim rngGroupStart As Range, cell As Range
    Application.ScreenUpdating = False
    With ActiveSheet
        'start festlegen  
        Set rngGroupStart = .Range("A5")  
        'Verbindungen der Spalten M:L lösen  
        .Range("M:L").UnMerge  
        'Für jede Zelle von A5:A(ENDE)  
        For Each cell In .Range("A5:A" & .Cells(Rows.Count, "A").End(xlUp).Row)  
            ' Wenn die Zelle drunter einen anderen Wert hat als vom Gruppenstart  
            If cell.Offset(1, 0).Value <> rngGroupStart.Value Then
                'Wenn mindestens zwei Zellen betroffen sind, starte Merge  
                If (cell.Row - rngGroupStart.Row) > 0 Then
                    'Merge in Spalten M und L vornehmen  
                    .Range(.Cells(rngGroupStart.Row, "L"), .Cells(cell.Row, "L")).Merge  
                    .Range(.Cells(rngGroupStart.Row, "M"), .Cells(cell.Row, "M")).Merge  
                End If
                'nächsten Gruppenstart festlegen  
                Set rngGroupStart = cell.Offset(1, 0)
            End If
        Next
    End With
Errhandler:
    Application.ScreenUpdating = True
End Sub