Musterlösungen: Dateien verschieben abhängig vom Teil des Dateinamens

@echo off & setlocal
set "Ordner=D:\Dein Ordner"  

pushd "%Ordner%"  
for /f "delims=" %%i in ('dir /b *_*') do (  
    for /f "delims=_" %%a in ("%%i") do (  
        for /f %%n in ('dir "%%a_*.*"2^>nul^|findstr "Datei(en)"') do if %%n gtr 1 (  
            md "%%a" 2>nul  
            move "%%a_*.*" "%%a">nul  
        )
    )
)
popd

# Gibt den Quellpfad der Dateien an
$source = "C:\test"  

# Schreibt alle Dateien auf der obersten Ebene in ein Array
$files = gci $source | ?{$_.Mode -eq '-a---'}  

foreach ($f in $files){
    # Spaltet den String an einer beliebigen Stelle auf, an der der Separator vorhanden ist
    $dublette = $f -split '__'  
    # Zähler, wie häufig das erste Element vorhanden ist
    $counter = $files -match $dublette
    # Definieren des Zielpfades
    $destpath = $source +"\" +$dublette  
    # Wenn eine Dublette vorhanden ist und das Verzeichnis noch nicht vorhanden ist, wird es erstellt und alle Dateien mit diesem Schema werden dorthin verschoben
    if ( $counter.Count -gt 1){
        $search = Test-Path $destpath
        if ($search -eq $false){
            New-Item $destpath -ItemType directory
        }
    Move-Item $source\$f -Destination $destpath
    } 
}

@echo off & setlocal
set "Ordner=D:\Dein Ordner"  
set "Separator=_"  

REM voruebergehend in den angegebenen Ordner wechseln
pushd "%Ordner%"  
REM in einer Schleife alle passenden Dateien (mit dem Separator im Namen; keine Ordner) abarbeiten
for /f "delims=" %%i in ('dir /b/a-d "*%Separator%*"') do (  
    REM Anfangsstring isolieren
    for /f "delims=%Separator%" %%a in ("%%i") do (  
        REM Anzahl der mit dem Anfangsstring beginnenden Dateien ermitteln und
        REM wenn mehr als eine Datei vorhanden ist ...
        for /f %%n in ('dir "%%a%Separator%*.*"2^>nul^|findstr "Datei(en)"') do if %%n gtr 1 (  
            REM ... den Zielordner erstellen (falls bereits vorhanden Fehlermeldung nicht anzeigen) ...
            md "%%a" 2>nul  
            REM ... und alle entsprechenden Dateien in den Zielordner verschieben
            move "%%a%Separator%*.*" "%%a">nul  
        )
    )
)
REM Wechsel des Ordners rückgängig machen
popd

@echo off & setlocal
set "Ordner=D:\Dein Ordner"  
set "Separator= - "  

pushd "%Ordner%"  
for /f "delims=" %%i in ('dir /b/a-d "*%Separator%*"') do (  
    set "Name=%%~ni"  
    setlocal enabledelayedexpansion
    call set "Anfang=%%Name:%Separator%!Name:*%Separator%=!=%%"  
    for /f %%n in ('dir "!Anfang!%Separator%*.*"2^>nul^|findstr "Datei(en)"') do if %%n gtr 1 (  
        md "!Anfang!" 2>nul  
        move "!Anfang!%Separator%*.*" "!Anfang!">nul  
    )
    endlocal
    )
)
popd

Ordner = "D:\Dein Ordner"  
Separator = " - "  

Set fso = CreateObject("Scripting.FileSystemObject")  
For Each File In fso.GetFolder(Ordner).Files
    If InStr(File.Name, Separator) > 0 Then    
        Anfang = Split(File.Name, Separator)(0)
        L = Len(Anfang & Separator)
        Anzahl = 0
        For Each Testfile In fso.GetFolder(Ordner).Files
            If LCase(Left(TestFile.Name, L)) = LCase(Anfang & Separator) Then Anzahl = Anzahl + 1
        Next
        If Anzahl > 1 Then
            Ziel = Ordner & "\" & Anfang  
            If Not fso.FolderExists(Ziel) Then fso.CreateFolder(Ziel)
            fso.MoveFile Ordner & "\" & Anfang & Separator & "*", Ziel & "\"  
        End If
    End If
Next

@echo off & setlocal
set "Ordner=D:\Dein Ordner"  
set "Separator=_"  

REM voruebergehend in den angegebenen Ordner wechseln
pushd "%Ordner%"  
REM in einer Schleife alle passenden Dateien (mit dem Separator im Namen; keine Ordner) abarbeiten
for /f "delims=" %%i in ('dir /b/a-d "*%Separator%*"') do (  
    REM 2. String isolieren
    for /f "tokens=2 delims=%Separator%" %%a in ("%%i") do (  
        REM Anzahl der mit dem String endendem Dateien ermitteln und
        REM wenn mehr als eine Datei vorhanden ist ...
        for /f %%n in ('dir "*%Separator%%%a.*"2^>nul^|findstr "Datei(en)"') do if %%n gtr 1 (  
            REM ... den Zielordner erstellen (Name des Ordners ohne Typ, zB ".txt") -  
            REM (falls bereits vorhanden, Fehlermeldung nicht anzeigen) ...
            md "%%~na" 2>nul  
            REM ... und alle entsprechenden Dateien in den Zielordner verschieben
            move "*%Separator%%%a" "%%~na">nul  
        )
    )
)
REM Wechsel des Ordners rückgängig machen
popd