ab einer bestimmten Zeile nachfolgende zeilen in eine txt schreiben

Servus zusammen

ich habe da ein kleines problem

für euch bestimmt nicht

Eigentlich ganz einfach in der aufgabenstellung aber in der ausführung doch nicht so (für mich zumindest)!

Ich habe eine backup.log

ab der zeile wo folgende zeichenkette ist: ===============<ENDE DER BACKUP-PROTOKOLLDATEI>==================

soll diese zeile und alle folgenden in eine seperate txt-file geschriebn werden

ich habe es aber nur geschaft die eine zeile anzeigen zu lassen aber nicht die folgenden!

Könnt ihr mir da eine einfache Lösung zeigen?

Das wäre Super

grüße

Compane

Bitte markiere auch die Kommentare, die zur Lösung des Beitrags beigetragen haben

Content-ID: 98168

Url: https://administrator.de/forum/ab-einer-bestimmten-zeile-nachfolgende-zeilen-in-eine-txt-schreiben-98168.html

Ausgedruckt am: 22.12.2024 um 23:12 Uhr

9 Kommentare

Neuester Kommentar

Hallo Compane!

Etwa so:

@echo off & setlocal
set "Log=D:\backup.log"  
set "Txt=D:\Eine separate Textdatei.txt"  
set Kennzeichen="===============<ENDE DER BACKUP-PROTOKOLLDATEI>=================="  

set Zeile=
for /f "delims=:" %%i in ('findstr /n /c:%Kennzeichen% "%Log%"') do if not defined Zeile set Zeile=%%i  
set /a Zeile-=1
more +%Zeile% "%Log%" > "%Txt%"  

Grüße
bastla

servus bastla

es funktioniert nicht

ich bekomme aber auch keine fehlermeldung!

ahh funktioniert doch

danke nochmal für die schnelle hilfe

grüße nochmal kann es sein das bestimmte .txt dateien irgentwelche attribute haben wommit das script nichts anfangen kann???

ich habe eine txt die ist 13kb groß und eine andere die ich selber erstellt habe mit dem gleichen inhalt (per hand hinein copiert) die ist 7 kb groß

die 7kb datei funktioniert mit dem script die andere nicht ???

Woran kann das liegen???

Hallo Compane!

Unicode?

Grüße
bastla

jetzt haste mich eiskalt erwischt

wie kann ich das entfernen oder nochbesser wäre natürlich wenn ich das script erweitern kann und mir nur den inhalt heraushole (per hand Funktioniert das ja)!

oder zumindest auf das script erweitern

Hallo Compane!

Sollte so gehen:

@echo off & setlocal
set "Log=Z:\Ein.log"  
set "Txt=Z:\Eine separate Textdatei.txt"  
set Kennzeichen="===============<ENDE DER BACKUP-PROTOKOLLDATEI>=================="  

set T=%temp%\LogTemp.txt
type "%Log%" > %T%  
set Zeile=
for /f "delims=:" %%i in ('findstr /n /c:%Kennzeichen% "%T%"') do if not defined Zeile set Zeile=%%i  
if not defined Zeile (echo "Text nicht gefunden!" & goto :eof)  
set /a Zeile-=1
more +%Zeile% %T% > "%Txt%"  