Dateien im Ordner auslesen und per email senden

Hallo

Habe jetzt folgendes Skript:

:: Festlegen der Variablen für Quell und Zielverzeichniss...

Set "Quell=C:Inetpubftprootsapfehler"
Set message=SAPXI-FEHLER am %time% um %date% entdeckt
Set body=Liste aller Dateien in dem Fehlerordner
Set HINWEISTEXT01=Hallo
Es sind %X% Fehler aufgetreten
Set HINWEISTEXT02=Bitte die Fehler schnell beseitigen
MfG

Der Fehler-Support

for /f %%i in ('dir /b /od %Quell%"DEB_*.*"') do @set Neueste=%%i
c:atchlatlat.exe %Quell%%Neueste% -to administrator@domain.de -server EMAILSERVER -subject "%message%"

:: pause

Das funktioniert so auch einwandfrei.
Ich bekomme den Inhalt der Neusten Datei als Inhalt zugemailt. Allerdings nur von Dateien, die mit DEB_ anfangen.


Zur Veranschaulichung (Stand):
AN / VON: administrator@domain.de
BETREFF: SAPXI-FEHLER am %time% um %date% entdeckt
INHALT: Inhalt der Datei, die am neusten ist.


GEWÜNSCHT:
AN / VON: administrator@domain.de
BETREFF: SAPXI-FEHLER am %time% um %date% entdeckt
INHALT:
Es sind X Fehlerdateien vorhanden!
HINWEISTEXT01

1. Datei:
Name der Datei inkl. Erstellungsdatum /-zeit
Inhalt der Datei

2. Datei:
Name der nächsten Datei inkl. Erstellungsdatum /-zeit
und deren Inhalt


HINWEISTEXT02

Folgendes Problem kommt noch hinzu. In dem Ordner können sich drei verschiedene Typen von Dateien
befinden. Ich möchte aber nur, dass davon zwei Dateien durchsucht werden. Diese fangen mit DEB_ bzw.
KRE_ an.

Ich bin in Sachen BATCH kompletter Neuling und wäre für Hilfe sehr dankbar.
Einiges habe ich jetzt schon hinbekommen - aber das ist doch wohl etwas schwieriger????!!!!!

Ich hoffe, dass ich mein Anliegen recht gut veranschlichen konnte.

Viele Grüße

Webbi1976

@echo off & setlocal
Set "Quell=C:\Inetpub\ftproot\sapfehler"  
Set message=SAPXI-FEHLER am %time% um %date% entdeckt
::HINWEISTEXT01 wegen der einzufügenden Anzahl direkt per "echo" - s. u. 
Set "HINWEISTEXT02=Bitte die Fehler schnell beseitigen"  
Set "HINWEISTEXT03=MfG Der Fehler-Support"  
set /a Anzahl=0
set "bodytemp=%Quell%\bodytemp.txt"  
set "body=%Quell%\body.txt"  
if exist "%bodytemp%" del "%bodytemp%"  
for /f %%i in ('dir /b /od "%Quell%\DEB_*.*"') do call :ProcessLine "%%i"  
for /f %%i in ('dir /b /od "%Quell%\KRE_*.*"') do call :ProcessLine "%%i"  
echo Es sind %Anzahl% Fehlerdateien vorhanden!>"%body%"  
echo.>>"%body%"  
type "%bodytemp%">>"%body%"  
echo %hinweistext02%>>"%body%"  
echo %hinweistext03%>>"%body%"  
c:\Patch\Blat\blat.exe "%body%" -to administrator@domain.de -server EMAILSERVER -subject "%message%"  
del "%bodytemp%"  
del "%body%"  
goto :eof
:ProcessLine
echo %~nx1 - %~t1>>"%bodytemp%"  
type %1>>"%bodytemp%"  
echo.>>"%bodytemp%"  
set /a Anzahl+=1
goto :eof

@echo off & setlocal
Set "Quell=C:\Inetpub\ftproot\sapfehler"  
Set message=SAPXI-FEHLER am %time% um %date% entdeckt
Set "HINWEISTEXT02=Bitte die Fehler schnell beseitigen"  
Set "HINWEISTEXT03=MfG Der Fehler-Support"  
set /a Anzahl=0
set "bodytemp=%Quell%\bodytemp.txt"  
set "body=%Quell%\body.txt"  
if exist "%bodytemp%" del "%bodytemp%"  
for /f "delims=" %%i in ('dir /b /od "%Quell%\DEB_*.*"') do call :ProcessLine "%Quell%\%%i"  
for /f "delims=" %%i in ('dir /b /od "%Quell%\KRE_*.*"') do call :ProcessLine "%Quell%\%%i"  
echo Es sind %Anzahl% Fehlerdateien vorhanden!>"%body%"  
echo.>>"%body%"  
type "%bodytemp%">>"%body%"  
echo.>>"%body%"  
echo %hinweistext02%>>"%body%"  
echo %hinweistext03%>>"%body%"  
c:\Patch\Blat\blat.exe "%body%" -to administrator@domain.de -server EMAILSERVER -subject "%message%"  
del "%bodytemp%"  
del "%body%"  
goto :eof
:ProcessLine
echo %~nx1 - %~t1>>"%bodytemp%"  
type %1>>"%bodytemp%"  
echo.>>"%bodytemp%"  
echo.>>"%bodytemp%"  
set /a Anzahl+=1
goto :eof