Dateien in Unterverzeichnissen konvertieren und kopieren

Hallo Liebe Community,
mit dem Skript unten möchte ich alle FLAC Dateien aus %src_dir%\Interpreter_x\Album_y\Datei_z.flac in
%dest_dir%\Interpreter_x\Album_y\Datei_z.mp3 kopieren/konvertieren.(Interpreter_x, Album_y und Datei_z stehen für beliebige Verzeinisse, Dateien)
Leider landen momentan alle konvertierten MP3 Dateien unter %dest_dir%\Datei_z.mp3
Da ich mich mit String-Operatoren nicht auskenne wollte ich diesbezüglich um Eure Hilfe bitten.
Die Zieldatei wird im letzten Parameter von lame als "%dest_dir%\%%~nx.mp3"festgelegt, das sollte bearbeitet werden.
Vielen Dank für Eure Hilfe im Voraus!
unicum

@echo on
::
set src_dir=g:\test\film
set temp_dir=g:\temp
set dest_dir=d:\archiv
set exedir=g:\test
::
xcopy %src_dir% %dest_dir% /T /E /I
for /r %src_dir% %%x in (dir /b *.flac) do (
%exedir%\flac -d "%%x" -o "%temp_dir%\%%~nx"
%exedir%\lame -V2 "%temp_dir%\%%~nx" "%dest_dir%\%%~nx.mp3"
del "%temp_dir%\%%~nx"
)

@echo on & setlocal
::
set src_dir=g:\test\film
set temp_dir=g:\temp
set dest_dir=d:\archiv
set exedir=g:\test
::
xcopy "%src_dir%" "%dest_dir%\" /E  
for /r %src_dir% %%x in (*.flac) do (
    "%exedir%\flac" -d "%%x" -o "%temp_dir%\%%~nx"  
    if not errorlevel 1 "%exedir%\lame" -V2 "%temp_dir%\%%~nx" "%dest_dir%\%%~nx.mp3" && del "%temp_dir%\%%~nx"  
)

@echo on & setlocal
::
set src_dir=g:\test\film
set temp_dir=g:\temp
set dest_dir=d:\archiv
set exedir=g:\test
::
echo xcopy "%src_dir%" "%dest_dir%\" /T /E  
for /r "%src_dir%" %%x in (*.flac) do set "Full=%%~dpnx" & call :ProcessFile "%%x"  
goto :eof

:ProcessFile
call set "Rel=%%Full:%src_dir%\=%%"  
"%exedir%\flac" -d %1 -o "%temp_dir%\%~n1"  
if not errorlevel 1 "%exedir%\lame" -V2 "%temp_dir%\%~n1" "%dest_dir%\%Rel%.mp3" && del "%temp_dir%\%~n1"  
goto :eof

@echo on & setlocal
::
set src_dir=g:\test\film
set temp_dir=g:\temp
set dest_dir=d:\archiv
set exedir=g:\test
::
for /r %src_dir% %%x in (*.flac) do Call :Proc "%%~fx"  
Pause
Goto :Eof
:Proc
Set "FlacPath=%~dp1"  
Call Set "MpgPath=%%FlacPath:%src_dir%=%dest_dir%%%"  
"%exedir%\flac" -d %1 -o "%temp_dir%\%~n1"  
if not errorlevel 1 "%exedir%\lame" -V2 "%temp_dir%\%~n1" "%MpgPath%%~n1.mp3" && del "%temp_dir%\%~n1"