Email versenden wenn Dienst beendet

strComputer = "."   
SERVICENAME = "[DEIN SERVICE NAME]"  
MAILFROM = "[DEINE MAILADRESSE]"  
MAILTO = "[EMPFÄNGERADRESSE]"  
MAILSUBJECT = "[SUBJECT]"  
MAILBODY = "[MAILBODY]"  
MAILSERVER = "[SMTPSERVER]"  
MAILSERVER_USER = "[USERNAME]"  
MAILSERVER_PASSWORD = "[PASSWORT]"  


Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")   
Set colServices = objWMIService.ExecQuery("SELECT * FROM Win32_Service WHERE Name = '" & SERVICENAME & "'")   
For Each objService in colServices 
        if objService.State = "Stopped" then  
        	sendmail MAILFROM,MAILTO,MAILSUBJECT,MAILBODY
        End if
Next


Sub sendmail(FROMMAIL,TOMAIL,SUBJECT,BODY)
	Const cdoSendUsingPort = 2 'Send the message using the network (SMTP over the network).  
	Const cdoAnonymous = 0 'Do not authenticate  
	Const cdoBasic = 1 'basic (clear-text) authentication  
	Const cdoNTLM = 2 'NTLM  
	
	Dim objMessage
	Set objMessage = CreateObject("CDO.Message")  
	objMessage.Subject = SUBJECT
	objMessage.From = FROMMAIL
	objMessage.To = TOMAIL
	objMessage.TextBody = BODY
	
	
	'==This section provides the configuration information for the remote SMTP server.  
	
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2  
	
	'Name or IP of Remote SMTP Server  
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpserver") = MAILSERVER  
	
	'Type of authentication, NONE, Basic (Base64 encoded), NTLM  
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic  
	
	'Your UserID on the SMTP server  
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/sendusername") = MAILSERVER_USER ' Benutzername  
	
	'Your password on the SMTP server  
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/sendpassword") = MAILSERVER_PASSWORD ' Passwort  
	
	'Server port (typically 25)  
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25  
	
	'Use SSL for the connection (False or True)  
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False  
	
	'Connection Timeout in seconds (the maximum time CDO will try to establish a connection to the SMTP server)  
	objMessage.Configuration.Fields.Item _
	("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60  
	
	objMessage.Configuration.Fields.Update
	
	'==End remote SMTP server configuration section==  
	objMessage.Send
end sub