DKIM in MS Outlook überprüfen

Sub CheckDKIMHeaderForSelectedMail()
    Dim regex as Object, mail as Object, matches as Object
    With ActiveExplorer
        If .Selection.Count > 0 Then
            Set regex = CreateObject("vbscript.regexp")  
            regex.Global = False: regex.IgnoreCase = True: regex.MultiLine = True
            regex.pattern = "^Authentication-Results:[\s\S]*?dkim=(fail|pass)"  
            For Each mail In .Selection
                If mail.Class = olMail Then
                    Set matches = regex.Execute(mail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x007D001F"))  
                    If matches.Count > 0 Then
                        If LCase(matches(0).submatches(0)) = "pass" Then  
                            MsgBox "DKIM passed!", vbInformation  
                        Else
                            MsgBox "DKIM failed!", vbExclamation  
                        End If
                    Else
                        MsgBox "No DKIM information available.", vbExclamation  
                    End If
                End If
            Next
        Else
            MsgBox "Please select at least one email from your folder list."  
        End If
    End With
End Sub