Frage zum Verteilen von xml-Dateien nach ihren Inhalten auf der Grundlage von Daten aus Schlüsseldatei

Verschieben von xml-Datei aufgrund mehrerer Angaben aus externer Zuordnungsdatei

Hallo liebe Onliner,

nachdem ich das Forum rauf und runter durchsucht habe, und leider erst gerade mit Batch Programmierung begonnen habe, wende ich mich mit meinem Hilfeersuchen einmal an die fortgeschrittenen aus dem Forum:


Aus einem Abrechnungsprogramm erhalte ich pro Minute eine XML Datei "default.xml", die ich aufgrund von Bedingungen, die in einer Datei "Kostenstellen.txt" eingetragen ist, in Unterverzeichnisse z.B. 3080 für Kostenstelle 3080 verschieben möchte. Alles, was nicht sicher einer Kostenstelle zugeordnet werden kann, soll in einen Ordner c:\Rest geschoben werden


Kostenstellen.txt

"Keller-Stübchen"; x=230-240; y=700-801; c:\3080
"Keller - Stuebchen"; x=230-240; y=700-801; c:\3080
"Bar-Raum"; x=123-240; y=100-151; C:\2060
(...)

Legende:
"Suchtext";valider Range für coordx;valider Range für coordy; Zielverzeichnis


eintreffende XML Dateien "c:\Data\Default.xml" mit foldendem Inhalten

<roomiD Coordx="225" Coordy="856">"Keller-Stübchen"</roomid>
<roomiD Coordx="225" Coordy="856">"keller-stuebchen"</roomid>
<roomiD Coordx="225" Coordy="856">"Barraum"</roomid>
<roomiD Coordx="235" Coordy="456">"Keller - Stübchen"</roomid>
(...)

Kiffelig wird es nun dadurch,
dass z.B. der Wert "Keller-Stübchen" in der xml-Datei zwar mehrfach auftauchen kann, aber immer von eindeutigen Werten für Coordx und Coordy begleitet wird und nur dann einer Kostenstelle zugeordnet werden darf, wenn wenigstens ein Vorkommen bezgl. beider Koordinaten im durch die Datei Kostenstellen.txt vorgegeben Range liegt.

Den Inhalt der Datei "Kostenstellen.txt" kann ich beeinflussen,
also z.B. auch für Umlaut-/Sonderzeichenvarienten, die in der XML-Datei vorkommen können, mehrere Einträge einstellen.

Die "Kostenstellen.txt" hat zwischen 50 und 60 Zeilen, die XML-Datei kann bis zu 500 Zeilen haben. Die XML Datei ist immer zunächst nach COORDX und dann nach COORDY soriert.


Gibt es eine Möglichkeit, die Zuordnung per Batch zu realisiern?
Bin für jede Idee dankbar.


Gruß
mispel

@echo off & setlocal
set "XML=C:\default.xml"  
set "KStListe=C:\Kostenstellen.txt"  
set "Rest=C:\Rest"  

set Ziel=
for /f "usebackq tokens=1-2 delims=<>" %%i in ("%XML%") do (  
	for /f "tokens=3,5 delims== " %%x in ("%%i") do (  
		set "KSt=%%~j" & set "X=%%~x" & set "Y=%%~y" & call :ProcessLine  
	)
)
if not defined Ziel set "Ziel=%Rest%"  
echo move "%XML%" "%Ziel%\"  
goto :eof

:ProcessLine
if defined Ziel goto :eof
findstr /i "%KSt%" "%KStListe%">nul || goto :eof  

for /f "tokens=2-4 delims=; " %%i in ('findstr /i /c:"%KSt%" "%KStListe%"') do set "XRange=%%i" & set "YRange=%%j" & set "Ordner=%%k"  
for /f "tokens=2,3 delims==-" %%i in ("%XRange%") do set "XLow=%%i" & set "XHigh=%%j"  
for /f "tokens=2,3 delims==-" %%i in ("%YRange%") do set "YLow=%%i" & set "YHigh=%%j"  

if %X% lss %XLow% goto :CheckY
if %X% leq %XHigh% set "Ziel=%Ordner%" & goto :eof  
:CheckY
if %y% lss %YLow% goto :eof
if %Y% leq %YHigh% set "Ziel=%Ordner%"  
goto :eof

if %X% lss %XLow% goto :CheckY

if %X% leq %XHigh% set "Ziel=%Ordner%" & goto :eof  

if %X% lss %XLow% goto :eof
if %X% gtr %XHigh% goto :eof
if %y% lss %YLow% goto :eof
if %Y% gtr %YHigh% goto :eof
set "Ziel=%Ordner%"  
goto :eof