Listbox nach String der Reihe nach Suchen und markieren (SpinButton)

Option Compare Text
' Ergebnis collection  
Dim sResults As New Collection
' aktuelle Position in der Ergebnisliste  
Dim sResultsPos As Integer

' Suchen Button click Prozedur  
Private Sub btnSearch_Click()
    ' finde Einträge mit Funktion  
    Set sResults = FindStringsInListBox(txtSearch.Text)
    ' Wenn Suche erfolgreich  
    If sResults.Count <> 0 Then
        MsgBox "Ergebnis gefunden in " & sResults.Count & " Zeilen.", vbInformation  
        ' Initiale Position für Ergebnisse festlegen  
        sResultsPos = 0
        ' aktiviere SpinButton  
        sb.Enabled = True
        ' markiere automatisch das erste Ergebnis  
        sb_SpinDown
    Else    ' Suche ergebnislos  
        ' Markierung entfernen  
        lb.ListIndex = -1
        ' deaktiviere SpinButton  
        sb.Enabled = False
        MsgBox "Kein Eintrag gefunden!", vbExclamation  
    End If
End Sub

' SpinUp Button  
Private Sub sb_SpinUp()
    If sResults.Count = 0 Then Exit Sub
    ' Position in der Ergebnisliste festlegen  
    sResultsPos = IIf(sResultsPos > 1, sResultsPos - 1, sResults.Count)
    ' markiere Ergebnis in Listbox  
    lb.ListIndex = sResults(sResultsPos)
End Sub
'SpinDown Button  
Private Sub sb_SpinDown()
    If sResults.Count = 0 Then Exit Sub
    ' Position in der Ergebnisliste festlegen  
    sResultsPos = IIf(sResultsPos < sResults.Count, sResultsPos + 1, 1)
    ' markiere Ergebnis in Listbox  
    lb.ListIndex = sResults(sResultsPos)
End Sub
' Funktion zum finden von Einträgen in der Listbox  
Function FindStringsInListBox(strTerm) As Collection
    Dim colRows As New Collection, found As Boolean, r as long, c as Integer
    With lb
        For r = 0 To .ListCount - 1
            found = False
            For c = 0 To .ColumnCount - 1
                If .List(r, c) Like "*" & strTerm & "*" Then  
                    found = True
                End If
            Next
            If found Then colRows.Add r
        Next
    End With
    Set FindStringsInListBox = colRows
End Function
' bei Textänderung in Suchbox  
Private Sub txtSearch_Change()
    If txtSearch.Text = "" Then  
        btnSearch.Enabled = False
    Else
        btnSearch.Enabled = True
    End If
End Sub